infra: trigger gp news lambda at 0 and 15 o'clock utc time

apps/gp-news/usw2dev/lambda.tf

@@ -14,3 +14,30 @@ resource "aws_lambda_function" "gp_news_lambda" {
 
   architectures = ["x86_64"]
 }
+
+resource "aws_cloudwatch_event_rule" "gp_news_periodic" {
+  count = length(var.schedule_daily_utc_time)
+
+  name                = "gp-news-scraper-periodic-trigger-${count.index}"
+  description         = "Trigger GP News scraper lambda daily at ${var.schedule_daily_utc_time[count.index]} UTC"
+  schedule_expression = "cron(${split(":", var.schedule_daily_utc_time[count.index])[1]} ${split(":", var.schedule_daily_utc_time[count.index])[0]} * * ? *)"
+}
+
+resource "aws_cloudwatch_event_target" "gp_news_scraper_lambda" {
+  count = length(var.schedule_daily_utc_time)
+
+  rule      = aws_cloudwatch_event_rule.gp_news_periodic[count.index].name
+  target_id = "GPNewsScraperLambda-${count.index}"
+  arn       = aws_lambda_function.gp_news_lambda.arn
+}
+
+resource "aws_lambda_permission" "allow_eventbridge" {
+  count = length(var.schedule_daily_utc_time)
+
+  statement_id  = "AllowExecutionFromEventBridge-${count.index}"
+  action        = "lambda:InvokeFunction"
+  function_name = aws_lambda_function.gp_news_lambda.function_name
+  principal     = "events.amazonaws.com"
+  source_arn    = aws_cloudwatch_event_rule.gp_news_periodic[count.index].arn
+}
+

apps/gp-news/usw2dev/terraform.auto.tfvars

@@ -1 +1,2 @@
 env_name = "usw2dev"
+schedule_daily_utc_time = ["00:00", "15:00"]

apps/gp-news/usw2dev/variables.tf

@@ -25,4 +25,10 @@ variable "num_versions_to_keep" {
   description = "Number of versions to keep"
   type        = number
   default     = 3
+}
+
+variable "schedule_daily_utc_time" {
+  description = "The UTC time to schedule the daily scraper (in HH:MM format)"
+  type        = list(string)
+  default     = ["00:00"]
 }