[W1][Codeunit][1032][Job Planning Line-Reserve] - TransferJobPlanningLineToItemJournalLineReservationEntry

[Duizy1971]

Why do you need this change?

I have requested similar issues based on the equivalent sales/purchase/transfer/service reserve codeunits in previous years.
We need to be able to transfer specific item tracking lines (T337 Reservation Entry) to the item journal line during the picking and shipping with our own warehouse module. The request is made in the same way it was implemented in codeunit 99000834 "Purch. Line-Reserve". I have no idea if you want to implement it differently without the use of the IsHandled pattern.

Describe the request

Old code:
procedure TransferJobLineToItemJnlLine(var JobPlanningLine: Record "Job Planning Line"; var NewItemJournalLine: Record "Item Journal Line"; TransferQty: Decimal): Decimal
...
TransferQty :=
CreateReservEntry.TransferReservEntry(Database::"Item Journal Line",
NewItemJournalLine."Entry Type".AsInteger(), NewItemJournalLine."Journal Template Name", NewItemJournalLine."Journal Batch Name", 0,
NewItemJournalLine."Line No.", NewItemJournalLine."Qty. per Unit of Measure", OldReservationEntry, TransferQty);
...
end;

New code:
procedure TransferJobLineToItemJnlLine(var JobPlanningLine: Record "Job Planning Line"; var NewItemJournalLine: Record "Item Journal Line"; TransferQty: Decimal): Decimal
...
TransferJobPlanningLineToItemJournalLineReservationEntry(JobPlanningLine, NewItemJournalLine, OldReservationEntry, TransferQty);
...
end;

local procedure TransferJobPlanningLineToItemJournalLineReservationEntry(var JobPlanningLine: Record "Job Planning Line"; var ItemJournalLine: Record "Item Journal Line"; var OldReservationEntry: Record "Reservation Entry"; var TransferQty: Decimal);
var
    IsHandled: Boolean;
begin
    IsHandled := false;
    OnBeforeTransferJobPlanningLineToItemJournalLineReservationEntry(JobPlanningLine, ItemJournalLine, OldReservationEntry, TransferQty, IsHandled);
    if IsHandled then
        exit;

    TransferQty :=
        CreateReservEntry.TransferReservEntry(
            Database::"Item Journal Line",
            ItemJournalLine."Entry Type".AsInteger(), ItemJournalLine."Journal Template Name",
            ItemJournalLine."Journal Batch Name", 0, ItemJournalLine."Line No.",
            ItemJournalLine."Qty. per Unit of Measure", OldReservationEntry, TransferQty);
end;

[IntegrationEvent(false, false)]
local procedure OnBeforeTransferJobPlanningLineToItemJournalLineReservationEntry(var JobPlanningLine: Record "Job Planning Line"; var ItemJournalLine: Record "Item Journal Line"; var OldReservationEntry: Record "Reservation Entry"; var TransferQty: Decimal; var IsHandled: Boolean);
begin
end;

Internal work item: AB#626514

[AleksandricMarko]

Hi @Duizy1971,

Thanks for submitting this extensibility request. To help us process it efficiently, please update the issue to include the required information.

📚 Extensibility Guidelines

Missing Information:

• Alternatives Evaluated: Which existing events or patterns were tried and why they are insufficient for your needs?

• Justification for IsHandled: Please provide a specific technical reason why a standard event or alternative approach won't work. Explain why bypassing the standard logic is essential for your scenario, not just that it was done this way in another codeunit.

• Performance Considerations: What is the expected execution frequency of this event and potential performance impact?

• Data Sensitivity Review: Please confirm whether sensitive data is exposed through the event parameters or provide rationale if exposure is necessary.

• Multi-Extension Interaction: What are the risks if multiple extensions subscribe to this event, and how would conflicts be mitigated?

Please update the issue with the missing details. We'll automatically re-analyze once updated.

[Duizy1971]

Alternatives Evaluated: TransferJobLineToItemJnlLine does not have any events and no usable ones in "Create Reserv. Entry". I cannot replace TransferJobLineToItemJnlLine in the Base at any point. I need to be able to post job usage on one specific item tracking line even if there are other item tracking lines.

Justification for IsHandled: ReservationEngineMgt.InitRecordSet(OldReservationEntry, ItemTrackingSetup) contains multiple buffers Temp336 and I have no way to filter out specific T337 that I don't want to be transferred. So filtering is out-of-the-question. That leaves an if then else construction to check if a OldReservationEntry should be transferred to the job journal line. Mind you this pattern ais already being used in most of the Reserve.Codeunit.al objects in the BaseApp. I have never run into a problem.

Performance Considerations: No impact; the base loop will only skip a few T336/337 records that I don't want to be transferred from the job planning line to the job journal line. Usually it is full shipping of job usage so the base code will mostly loop through all the item tracking lines anyway.

Data Sensitivity Review: As far as I can tell is this not the case.

Multi-Extension Interaction: In the case if I decide to skip an item tracking line but another app decides the other way, I guess my posting will raise an error because I check if only the specifiek TransferQty. is being handled.

[AleksandricMarko]

✅ Analysis complete - approved for implementation

---

Implementation:

Add a new local wrapper procedure in the TransferJobLineToItemJnlLine() procedure of Codeunit 1032 Job Planning Line-Reserve and raise a new IsHandled integration event before CreateReservEntry.TransferReservEntry(...).

Location in TransferJobLineToItemJnlLine() procedure (inside the reservation loop):

if ReservationEngineMgt.InitRecordSet(OldReservationEntry, ItemTrackingSetup) then
    repeat
        OldReservationEntry.TestItemFields(JobPlanningLine."No.", JobPlanningLine."Variant Code", JobPlanningLine."Location Code");

        if NewItemJournalLine."Entry Type" = NewItemJournalLine."Entry Type"::"Negative Adjmt." then
            // Set the tracking for the item journal inside the loop as it is cleared within TransferReservEntry
            CreateReservEntry.SetNewTrackingFromItemJnlLine(NewItemJournalLine);

        TransferJobPlanningLineToItemJournalLineReservationEntry(
            JobPlanningLine, NewItemJournalLine, OldReservationEntry, TransferQty);

        EndLoop := TransferQty = 0;
        if not EndLoop then
            if ReservationEngineMgt.NEXTRecord(OldReservationEntry) = 0 then
                if ItemTrackingFilterIsSet then begin
                    OldReservationEntry.ClearTrackingFilter();
                    ItemTrackingFilterIsSet := false;
                    EndLoop := not ReservationEngineMgt.InitRecordSet(OldReservationEntry);
                end else
                    EndLoop := true;
    until EndLoop;

local procedure TransferJobPlanningLineToItemJournalLineReservationEntry(var JobPlanningLine: Record "Job Planning Line"; var ItemJournalLine: Record "Item Journal Line"; var OldReservationEntry: Record "Reservation Entry"; var TransferQty: Decimal)
var
    IsHandled: Boolean;
begin
    IsHandled := false;
    OnBeforeTransferJobPlanningLineToItemJournalLineReservationEntry(JobPlanningLine, ItemJournalLine, OldReservationEntry, TransferQty, IsHandled);
    if IsHandled then
        exit;

    TransferQty :=
        CreateReservEntry.TransferReservEntry(
            Database::"Item Journal Line",
            ItemJournalLine."Entry Type".AsInteger(), ItemJournalLine."Journal Template Name",
            ItemJournalLine."Journal Batch Name", 0, ItemJournalLine."Line No.",
            ItemJournalLine."Qty. per Unit of Measure", OldReservationEntry, TransferQty);
end;

Event Publisher (add at the end of the codeunit with other events):

[IntegrationEvent(false, false)]
local procedure OnBeforeTransferJobPlanningLineToItemJournalLineReservationEntry(var JobPlanningLine: Record "Job Planning Line"; var ItemJournalLine: Record "Item Journal Line"; var OldReservationEntry: Record "Reservation Entry"; var TransferQty: Decimal; var IsHandled: Boolean)
begin
end;

---

File: JobPlanningLineReserve.Codeunit.al