Refactor G/L Entry Review logic and add upgrade handling for review entries

Author: Bertverbeek4PS

Apps/W1/ReviewGLEntries/app/src/codeunits/ReviewGLEntry.Codeunit.al

@@ -20,6 +20,9 @@ codeunit 22200 "Review G/L Entry" implements "G/L Entry Reviewer"
     procedure ReviewEntries(var GLEntry: Record "G/L Entry");
     var
         GLEntryReviewLog: Record "G/L Entry Review Log";
+#if not CLEAN27
+        GLEntryReviewEntry: Record "G/L Entry Review Entry";
+#endif
         FeatureTelemetry: Codeunit "Feature Telemetry";
         UserName: Code[50];
         Identifier: Integer;
@@ -39,8 +42,11 @@ codeunit 22200 "Review G/L Entry" implements "G/L Entry Reviewer"
             GLEntry."Amount to Review" := 0;
             GLEntry.Modify(true);
         until GLEntry.Next() = 0;
+#if not CLEAN27
+        OnAfterReviewEntries(GLEntry, GLEntryReviewEntry);
+#endif
 
-        OnAfterReviewEntries(GLEntry, GLEntryReviewLog);
+        OnAfterReviewEntriesLog(GLEntry, GLEntryReviewLog);
 
         FeatureTelemetry.LogUptake('0000J2W', 'Review G/L Entries', "Feature Uptake Status"::Used);
         FeatureTelemetry.LogUsage('0000KQJ', 'Review G/L Entries', 'Review G/L Entries');
@@ -115,8 +121,16 @@ codeunit 22200 "Review G/L Entry" implements "G/L Entry Reviewer"
         end;
     end;
 
+#if not CLEAN27
+    [Obsolete('Use the event OnAfterReviewEntriesLog instead.', '27.0')]
     [IntegrationEvent(false, false)]
-    local procedure OnAfterReviewEntries(var GLEntry: Record "G/L Entry"; var GLEntryReviewLog: Record "G/L Entry Review Log")
+    local procedure OnAfterReviewEntries(var GLEntry: Record "G/L Entry"; var GLEntryReviewLog: Record "G/L Entry Review Entry")
+    begin
+    end;
+#endif
+
+    [IntegrationEvent(false, false)]
+    local procedure OnAfterReviewEntriesLog(var GLEntry: Record "G/L Entry"; var GLEntryReviewLog: Record "G/L Entry Review Log")
     begin
     end;
 }

Apps/W1/ReviewGLEntries/app/src/codeunits/Upgrade.Codeunit.al

@@ -0,0 +1,45 @@
+namespace Microsoft.Finance.GeneralLedger.Review;
+using System.Upgrade;
+codeunit 22201 "Upgrade"
+{
+    Access = Internal;
+    Subtype = Upgrade;
+
+    trigger OnUpgradePerCompany()
+    begin
+        MovetoGLEntryReviewLog();
+    end;
+
+    local procedure MovetoGLEntryReviewLog()
+    var
+        GLEntryReviewEntry: Record "G/L Entry Review Entry";
+        GLEntryReviewLog: Record "G/L Entry Review Log";
+        UpgradeTag: Codeunit "Upgrade Tag";
+    begin
+        if UpgradeTag.HasUpgradeTag(UpgradeReviewGLEntryTag) then exit;
+
+        if GLEntryReviewEntry.FindSet() then
+            repeat
+                GLEntryReviewLog.Init();
+                GLEntryReviewLog."G/L Entry No." := GLEntryReviewEntry."G/L Entry No.";
+                GLEntryReviewLog."Reviewed Identifier" := GLEntryReviewEntry."Reviewed Identifier";
+                GLEntryReviewLog."Reviewed By" := GLEntryReviewEntry."Reviewed By";
+                GLEntryReviewLog."Reviewed Amount" := GLEntryReviewEntry."Reviewed Amount";
+                GLEntryReviewLog.Insert(true);
+            until GLEntryReviewEntry.Next() = 0;
+
+        UpgradeTag.SetUpgradeTag(UpgradeReviewGLEntryTag);
+    end;
+
+
+    [EventSubscriber(ObjectType::Codeunit, Codeunit::"Upgrade Tag", 'OnGetPerCompanyUpgradeTags', '', false, false)]
+    local procedure RegisterPerCompanyTags(var PerCompanyUpgradeTags: List of [Code[250]])
+    begin
+        PerCompanyUpgradeTags.Add(UpgradeReviewGLEntryTag());
+    end;
+
+    local procedure UpgradeReviewGLEntryTag(): Code[250]
+    begin
+        exit('MS-547765-UpdateReviewGLEntry-20250704');
+    end;
+}

Apps/W1/ReviewGLEntries/app/src/tables/GLEntryReviewEntry.Table.al

@@ -5,7 +5,6 @@ table 22216 "G/L Entry Review Entry"
     ObsoleteState = Pending;
     ObsoleteReason = 'Use "G/L Entry Review Log" instead.';
     ObsoleteTag = '27.0';
-    //TODO: Create data conversion codeunit to convert existing entries to the new table
     fields
     {
         field(1; "G/L Entry No."; Integer)
@@ -34,4 +33,27 @@ table 22216 "G/L Entry Review Entry"
             Clustered = true;
         }
     }
+
+    trigger OnInsert()
+    var
+        GLEntryReviewLog: Record "G/L Entry Review Log";
+    begin
+        GLEntryReviewLog.Init();
+        GLEntryReviewLog."G/L Entry No." := "G/L Entry No.";
+        GLEntryReviewLog."Reviewed Identifier" := "Reviewed Identifier";
+        GLEntryReviewLog."Reviewed By" := "Reviewed By";
+        GLEntryReviewLog."Reviewed Amount" := "Reviewed Amount";
+        GLEntryReviewLog.Insert(true);
+    end;
+
+    trigger OnDelete()
+    var
+        GLEntryReviewLog: Record "G/L Entry Review Log";
+    begin
+        GLEntryReviewLog.SetRange("G/L Entry No.", "G/L Entry No.");
+        if GLEntryReviewLog.FindSet() then
+            repeat
+                GLEntryReviewLog.Delete(true);
+            until GLEntryReviewLog.Next() = 0;
+    end;
 }