Query running forever

[powerthe900]

I was running a query on a project and it is stuck on Running query: Stage 10/10 - computing '#select#ff' for hours. I tried different projects and the same thing happened.

My query is

import cpp
import semmle.code.cpp.ir.IR

/** Holds if `i` is a narrowing conversion. */
predicate isNarrowingConversion(ConvertInstruction i) {
  i.getResultSize() < i.getUnary().getResultSize()
}

from ConvertInstruction conv, Type inputType, Type outputType, FunctionCall fc
where
fc.getTarget().getQualifiedName() = "accept" or fc.getTarget().getQualifiedName() = "accept4" and
conv.getEnclosingFunction().calls(fc.getTarget()) and
isNarrowingConversion(conv) and
inputType = conv.getUnary().getResultType() and
outputType = conv.getResultType()
select conv, "Narrowing conversion from " + inputType + " to " + outputType + "."

[rdmarsh2]

It looks like you're missing some parentheses around the or, which is leading to an unconstrained join (also called a Cartesian product) across multiple tables. In CodeQL, a() or b() and c() is parsed as a() or (b() and c()). In this case, since fc.getTarget().getQualifiedName() = "accept" doesn't set any requirements for the other variables, you'll get every possible combination of ConvertInstruction and two types, plus the results you were expecting where fc is a call to accept4.

I'd recommend using the autoformatter (alt+shift+F in the VS Code extension) to make these kinds of mistakes more obvious. In this particular case, the formatted code would look like this:

from ConvertInstruction conv, Type inputType, Type outputType, FunctionCall fc
where
  fc.getTarget().getQualifiedName() = "accept"
  or
  fc.getTarget().getQualifiedName() = "accept4" and
  conv.getEnclosingFunction().calls(fc.getTarget()) and
  isNarrowingConversion(conv) and

And the fixed code would look like this:

from ConvertInstruction conv, Type inputType, Type outputType, FunctionCall fc
where
  (
    fc.getTarget().getQualifiedName() = "accept"
    or
    fc.getTarget().getQualifiedName() = "accept4"
  ) and
  conv.getEnclosingFunction().calls(fc.getTarget()) and
  isNarrowingConversion(conv) and

[powerthe900]

thanks

[github-actions]

This issue is stale because it has been open 14 days with no activity. Comment or remove the stale label in order to avoid having this issue closed in 7 days.