Support filtering mix deps output

Makes it easier to report versions of specific dependencies by allowing
users (or tools) to pass dependency names as arguments to `mix deps`.

Warns when a dependency is not found, similar to `mix deps.unlock`.

Proposal: https://groups.google.com/g/elixir-lang-core/c/5tlLZ1yu4rQ/m/g7Z8fNWiBwAJ

Author: rhcarvalho

lib/mix/lib/mix/tasks/deps.ex

@@ -186,19 +186,37 @@ defmodule Mix.Tasks.Deps do
 
     * `--all` - lists all dependencies, regardless of specified environment
 
+  ## Filtering dependencies (since v1.20.0)
+
+  You can list specific dependencies by passing their names as arguments:
+
+      $ mix deps phoenix phoenix_live_view
+
+  This is particularly useful when you need to quickly check versions for
+  bug reports or similar tasks.
+
   """
 
   @impl true
   def run(args) do
     Mix.Project.get!()
-    {opts, _, _} = OptionParser.parse(args, switches: [all: :boolean])
+    {opts, apps, _} = OptionParser.parse(args, switches: [all: :boolean])
     loaded_opts = if opts[:all], do: [], else: [env: Mix.env(), target: Mix.target()]
 
+    deps = Mix.Dep.Converger.converge(loaded_opts)
+
+    # Sort deps when showing all; preserve input order when filtering
+    {deps, unknown} =
+      if apps == [] do
+        {Enum.sort_by(deps, & &1.app), []}
+      else
+        apps = Enum.map(apps, &String.to_atom/1)
+        filter_deps(deps, apps)
+      end
+
     shell = Mix.shell()
 
-    Mix.Dep.Converger.converge(loaded_opts)
-    |> Enum.sort_by(& &1.app)
-    |> Enum.each(fn dep ->
+    Enum.each(deps, fn dep ->
       %Mix.Dep{scm: scm, manager: manager} = dep
       dep = check_lock(dep)
       extra = if manager, do: " (#{manager})", else: ""
@@ -211,5 +229,18 @@ defmodule Mix.Tasks.Deps do
 
       shell.info("  #{format_status(dep)}")
     end)
+
+    # Warnings last for visibility
+    for app <- unknown do
+      shell.error("warning: unknown dependency #{app}")
+    end
+  end
+
+  defp filter_deps(deps, apps) do
+    deps_map = Map.new(deps, fn dep -> {dep.app, dep} end)
+    unknown = Enum.reject(apps, &Map.has_key?(deps_map, &1))
+
+    # Preserve apps order
+    {Enum.map(apps -- unknown, &deps_map[&1]), unknown}
   end
 end

lib/mix/test/mix/tasks/deps_test.exs

@@ -100,6 +100,45 @@ defmodule Mix.Tasks.DepsTest do
     end)
   end
 
+  test "filters dependencies by name" do
+    in_fixture("deps_status", fn ->
+      Mix.Project.push(DepsApp)
+
+      Mix.Tasks.Deps.run(["ok"])
+
+      assert_received {:mix_shell, :info, ["* ok (https://github.com/elixir-lang/ok.git) (mix)"]}
+      refute_received {:mix_shell, :info, ["* invalidvsn" <> _]}
+      refute_received {:mix_shell, :info, ["* invalidapp" <> _]}
+      refute_received {:mix_shell, :info, ["* noappfile" <> _]}
+      refute_received {:mix_shell, :info, ["* nosemver" <> _]}
+    end)
+  end
+
+  test "filters multiple dependencies by name" do
+    in_fixture("deps_status", fn ->
+      Mix.Project.push(DepsApp)
+
+      Mix.Tasks.Deps.run(["ok", "nosemver"])
+
+      assert_received {:mix_shell, :info, ["* ok (https://github.com/elixir-lang/ok.git) (mix)"]}
+      assert_received {:mix_shell, :info, ["* nosemver (deps/nosemver)"]}
+      refute_received {:mix_shell, :info, ["* invalidvsn" <> _]}
+      refute_received {:mix_shell, :info, ["* invalidapp" <> _]}
+      refute_received {:mix_shell, :info, ["* noappfile" <> _]}
+    end)
+  end
+
+  test "warns when filtering for unknown dependencies" do
+    in_fixture("deps_status", fn ->
+      Mix.Project.push(DepsApp)
+
+      Mix.Tasks.Deps.run(["ok", "notmydep"])
+
+      assert_received {:mix_shell, :info, ["* ok (https://github.com/elixir-lang/ok.git) (mix)"]}
+      assert_received {:mix_shell, :error, ["warning: unknown dependency notmydep"]}
+    end)
+  end
+
   test "prints list of dependencies and their status, including req mismatches and custom apps" do
     in_fixture("deps_status", fn ->
       Mix.Project.push(ReqDepsApp)