provide define macro to support proper use of goog.define

Using Closure defines [1] has always been possible by attaching
the appropriate JSDoc metadata to a var:

    (def ^{:jsdoc ["@define {boolean}"]}
      APP_DEBUG true)

When compiling with :optimizations :none however these defines cannot be
overridden.

This commit introduces a `cljs.core/define` macro that helps with
emitting proper `goog.define` calls. Defines done with `goog.define` can
be overriden at runtime by supplying `CLOSURE_UNCOMPILED_DEFINES` or
`CLOSURE_DEFINES`. [2]

    (ns your-app.core)
    (define APP_DEBUG true)

emits the following `goog.define` call:

    /** @define {boolean} */
    goog.define('your_app.core.APP_DEBUG', true)

When compiling with `:none` the map passed to `:closure-defines`
is now added to the main file, allowing `goog.define` to pick
the right value at runtime.

[1] https://developers.google.com/closure/compiler/docs/js-for-compiler?hl=en#tag-define
[2] http://google.github.io/closure-library/api/source/closure/goog/base.js.src.html#l51

Author: martinklepsch

src/main/clojure/cljs/closure.clj

@@ -1123,7 +1123,8 @@
 
 (defn output-main-file [opts]
   (let [asset-path (or (:asset-path opts)
-                       (util/output-directory opts))]
+                       (util/output-directory opts))
+        closure-defines (json/write-str (:closure-defines opts))]
     (case (:target opts)
       :nodejs
       (output-one-file opts
@@ -1134,10 +1135,12 @@
              "}\n"
              "require(path.join(path.resolve(\".\"),\"" asset-path "\",\"goog\",\"bootstrap\",\"nodejs.js\"));\n"
              "require(path.join(path.resolve(\".\"),\"" asset-path "\",\"cljs_deps.js\"));\n"
+             "goog.global.CLOSURE_UNCOMPILED_DEFINES = " closure-defines ";\n"
              "goog.require(\"" (comp/munge (:main opts)) "\");\n"
              "goog.require(\"cljs.nodejscli\");\n"))
       (output-one-file opts
-        (str "if(typeof goog == \"undefined\") document.write('<script src=\"" asset-path "/goog/base.js\"></script>');\n"
+        (str "var CLOSURE_UNCOMPILED_DEFINES = " closure-defines ";\n"
+             "if(typeof goog == \"undefined\") document.write('<script src=\"" asset-path "/goog/base.js\"></script>');\n"
              "document.write('<script src=\"" asset-path "/cljs_deps.js\"></script>');\n"
              "document.write('<script>if (typeof goog != \"undefined\") { goog.require(\"" (comp/munge (:main opts))
              "\"); } else { console.warn(\"ClojureScript could not load :main, did you forget to specify :asset-path?\"); };</script>');\n")))))

src/main/clojure/cljs/core.cljc

@@ -685,6 +685,36 @@
              :cljs (new js/Error (core/str "Unsupported binding key: " (ffirst kwbs)))))
         (reduce process-entry [] bents)))))
 
+(core/defmacro define
+  "Defines a var using `goog.define`. Passed default value must be
+  string, number or boolean.
+
+  Default value can be overridden at compile time using the
+  compiler option `:closure-defines`. When overriding the string
+  you need to pass to `:closure-defines` is the munged version
+  of the original var.
+
+  Example:
+    (ns your-app.core)
+    (define DEBUG! false)
+    ;; can be overridden with
+    :closure-defines {\"your_app.core.DEBUG_BANG_\" true}"
+  [sym default]
+  (assert-args define
+   (core/or (core/string? default)
+            (core/number? default)
+            (core/true? default)
+            (core/false? default)) "a string, number or boolean as default value")
+  (core/let [defname (cljs.compiler/munge (core/str *ns* "/" sym))
+             type    (core/cond
+                       (core/string? default) "string"
+                       (core/number? default) "number"
+                       (core/or (core/true? default) (core/false? default)) "boolean")]
+    `(do
+       (declare ~(symbol sym))
+       (~'js* ~(core/str "/** @define {" type "} */"))
+       (goog/define ~defname ~default))))
+
 (core/defmacro let
   "binding => binding-form init-expr