Integrate with agent-shell

[acmorrow]

Currently the MCP registrations rely on https://github.com/manzaltu/claude-code-ide.el, but they could probably work with https://github.com/xenodium/agent-shell once xenodium/agent-shell#136 is resolved.

[dangom]

Hi @acmorrow,

it was very interesting to go through the README and seeing your insights. This is a cool project, thanks for sharing.

Did you manage to get that integrated with agent-shell?
If not I may try to do so at some point in the near future.
If yes, it'd be great to start from where you left off - or hear what next ideas you may have had.

Regards,
Daniel

[acmorrow]

Hey @dangom thanks for checking it out and for your thoughts. I'm happy to hear you found it interesting. Answers to your questions:

Did you manage to get that integrated with agent-shell?

No, not yet. Last time I looked at agent-shell it didn't look quite ready for me to jump over to it from claude-code-ide.el. For one thing, it wasn't clear to me if it had per-project scoping like claude-code-ide.el does, and it also wasn't clear to me how I could get the MCP server integration to work.

If not I may try to do so at some point in the near future.

Please do! I'm happy to collaborate via PRs. However turnaround may be a little slow since I have work commitments which preempt spending time on this project. Note though that I use this project daily, so I'm definitely interested in seeing it continue.

If yes, it'd be great to start from where you left off - or hear what next ideas you may have had.

Well, I alluded to some of them in the readme and some others by filing the issues. Here are the things I've been considering:

• It looks like claude code has recently introdued lsp plugins. Do these render my lsp MCPs obsolete? Or is flowing through emacs still the right way? I can't quite see how to get the claude-code lsp plugin to be aware of the one emacs is running.
• Per Add support for project instead of projectile #1 I'm using projectile for a long time but I know project is probably more widely used. Supporting both would be ideal.
• I've noticed that sometimes that when using these tools, claude code will want to use the LSP integration to format a buffer that it modified, but that buffer isn't actually open. I think a find-file MCP is needed, so that we can tell it that it needs to open the file into a buffer before using the MCPs.
• Scary as it is, I think there is an argument to be made for giving claude access to straight eval, so it can script emacs.
• I've had some vague thoughts about letting it write and execute macros.
• It would be fascinating to let it integrate with dap-mode so it could drive a debugger.

Overall, I think it would be great to see this project get some wider visibility and feedback, so, if you have ideas or suggestions, filing issues or creating PRs is definitely encouraged.

[cassandracomar]

agent-shell works with claude-code-ide.el's mcp server like this:

(defvar agent-shell--last-tracked-buf nil
  "The last file-visiting buffer tracked for MCP last-active-buffer.")

(defun agent-shell--track-active-buffer ()
  "Track the active file-visiting buffer for the MCP tools server.
Added to `post-command-hook'; exits early if the current buffer
is not file-visiting or hasn't changed."
  (when-let* ((cur (current-buffer))
              (file-path (buffer-file-name cur))
              ((not (eq cur agent-shell--last-tracked-buf)))
              (expanded-path (expand-file-name file-path))
              ((bound-and-true-p claude-code-ide--session-ids))
              ((fboundp 'claude-code-ide-mcp-server--server-alive-p))
              ((claude-code-ide-mcp-server--server-alive-p)))
    (maphash (lambda (project-dir session-id)
               (when (string-prefix-p (expand-file-name project-dir)
                                      expanded-path)
                 (claude-code-ide-mcp-server-update-last-active-buffer
                  session-id cur)))
             claude-code-ide--session-ids)
    (setq agent-shell--last-tracked-buf cur)))

(define-advice claude-code-ide-mcp-project-info (:override ()
                                                  agent-shell--prefer-last-active)
  "Prefer :last-active-buffer over :buffer when reporting project info."
  (let ((context (claude-code-ide-mcp-server-get-session-context)))
    (if context
        (let* ((project-dir (plist-get context :project-dir))
               (last-active (plist-get context :last-active-buffer))
               (registered (plist-get context :buffer))
               (buffer (or (and last-active (buffer-live-p last-active) last-active)
                           (and registered (buffer-live-p registered) registered))))
          (format "Project: %s\nBuffer: %s\nFiles: %d"
                  project-dir
                  (if buffer (buffer-name buffer) "No active buffer")
                  (length (project-files (project-current nil project-dir)))))
      "No session context available")))

(use-package agent-shell
  :config
  (setq agent-shell-mcp-servers
        '(((name . "emacs")
           (type . "http")
           (headers . ())
           (url . (lambda ()
                    (require 'claude-code-ide)
                    (require 'claude-code-ide-mcp-server)
                    (claude-code-ide-emacs-tools-setup)
                    (let* ((project-dir (agent-shell-cwd))
                           (session-id (format "agent-shell-%s-%s"
                                               (file-name-nondirectory
                                                (directory-file-name project-dir))
                                               (format-time-string "%Y%m%d-%H%M%S")))
                           (buffer (current-buffer)))
                      (claude-code-ide-mcp-server-register-session
                       session-id project-dir buffer)
                      (puthash project-dir session-id claude-code-ide--session-ids)
                      (add-hook 'post-command-hook
                                #'agent-shell--track-active-buffer)
                      (format "http://localhost:%d/mcp/%s"
                              (claude-code-ide-mcp-server-ensure-server)
                              session-id)))))))

there appears to be a bug in claude-code-ide.el's last-active-buffer tracking where it reports :buffer as the last active buffer even when :last-active-buffer is set. this always shows the agent-shell buffer to Claude Code as the currently active buffer -- the advice fixes it so it shows the last active file-visiting buffer.

edit: this project works perfectly in agent-shell by loading the claude-code-ide-extras modules right after loading claude-code-ide.