Suggestions about UrlDownloadToFile

[hanamichi77777]

Depending on my company's network, UrlDownloadToFile may not work and may not be able to download.
Using MSXML2.XMLHTTP60 allows for stable downloads, except for FireFox.
So, in order to support FireFox, I first tried running MSXML2.XMLHTTP60, and if there is an error, I suggest that UrlDownloadToFile be used.

   'UrlDownloadToFile 0&, StrPtr(Url), StrPtr(tmpInstallZipPath), 0&, 0&
    
   'Replace
    Dim flg As Boolean: flg = False
    Dim client As New MSXML2.XMLHTTP60
    client.Open "GET", Url, False
    On Error GoTo UrlDlFile 'FireFox
    client.send
    On Error GoTo 0
    If client.Status <> 200 Then
        Err.Raise 1, "WebDriverManager", "Error: Driver Download Not Successful"
    End If
    Const adTypeBinary = 1
    Const adSaveCreateNotExist = 2
    Dim binaryStream As New ADODB.stream
    binaryStream.Type = adTypeBinary
    binaryStream.Open
    binaryStream.Position = 0
    binaryStream.Write client.responseBody
    binaryStream.SaveToFile tmpInstallZipPath, adSaveCreateNotExist
    binaryStream.Close
    flg = True
        
UrlDlFile:
    If flg = False Then
      UrlDownloadToFile 0&, StrPtr(Url), StrPtr(tmpInstallZipPath), 0&, 0&
    End If

[6DiegoDiego9]

It's ok for me. However, since it's used two times in SeleniumVBA, and in separate classes, we need it as a Friend Function.
Mike?

[GCuser99]

Ha! we both posted at the same time.

[GCuser99]

As I recall, I think MSXML2.XMLHTTP60 worked for @6DiegoDiego9 back when we discussed this issue, but as you point out in your excellent post above, it did not work for Firefox - thus the reason to go with UrlDownloadToFile. I'm unable to test on a work network (only home use), but your suggestion looks reasonable to me.

It does raise the tangential issue of whether to continue to support Firefox. The code base contains a number of hacks to facilitate that support, several of which I think raise our TotalVirus score (UrlDownloadToFile being one of them). The only other place that we use UrlDownloadToFile is in the DownloadResource method of the WebDriver class. I think I can refactor that method using pure CDP while maintaining most of the functionality.

On the other hand, despite the low percentage of Windows Firefox users worldwide, we have had a surprising number of SeleniumVBA users post issues related to Firefox. So I'm reluctant to eliminate that without very good reason. When I have time, I think I'm going to produce another test without Firefox and UrlDownloadToFile support to see if that significantly reduces false-positives.

Anyway, I'm good with making your suggested change if it works for @6DiegoDiego9.

[6DiegoDiego9]

I'm not personally a Firefox user; however, I acknowledge all your worries, Mike.

Regarding the change, I propose placing it in WebShared, just under Public Declare PtrSafe Function UrlDownloadToFile ........., with this signature:
Friend Public Function DownloadToFile(Url As String, fileFullPath As String) As Boolean

[GCuser99]

@hanamichi77777, can you add one more technique to your test matrix (WinHttp.WinHttpRequest.5.1)? As I understand it, it handles redirects elegantly...

Public Function downloadToFile(ByVal Url As String, ByVal fileFullPath As String) As Boolean
    Dim client As Object
    Dim bytes() As Byte
    
    ' Create WinHTTP client
    Set client = CreateObject("WinHttp.WinHttpRequest.5.1")
    
    ' Enable automatic redirect handling
    client.Option(6) = True   ' WinHttpRequestOption_EnableRedirects
    
    ' Open and send request
    client.Open "GET", Url, False
    client.setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64)"
    client.send
    
    ' Check for success
    If client.Status = 200 Then
        bytes = client.ResponseBody
        saveByteArrayToFile bytes, fileFullPath
        downloadToFile = True
    End If
End Function

[hanamichi77777]

Thank you for @GCuser99
Unfortunately, downloading using automatic proxy failed.
I get the error "Unable to connect to server."
I think the following points are correct
@6DiegoDiego9

WinHTTP auto-proxy via VBA-Web:
If I remember correctly, the function was fairly complex, and more than 100 lines long. I used it (or another complex one) for another http->centered project, but for SeleniumVBA that could be too much. Am I mistaken?

Details are in the image below.

[GCuser99]

Thanks @hanamichi77777. Bummer...

The reason why Firefox is not working for XMLHTTP60 when Edge/Chrome do is because the geckodriver download Url is redirected, and XMLHTTP60 does not support redirection.

Another example of where XMLHTTP60 fails is in the DownloadResource method, when downloading from a redirected Url such as "https://github.com/GCuser99/SeleniumVBA/raw/main/dev/logo/logo.png" which gets redirected to "https://raw.githubusercontent.com/GCuser99/SeleniumVBA/main/dev/logo/logo.png".

I wonder why your Office network 1 does not like UrlDownloadToFile? Do you think it is a security policy?

So unfortunately, I don't believe your proposed solution will work on your Office network 1.

Can you try this "double fallback" solution on your Office network 1?

If the MSXML2.ServerXMLHTTP60 fallback does not work on that network, then please try the WinHttp.WinHttpRequest.5.1 method I shared above.

Public Function downloadToFile(ByVal Url As String, ByVal fileFullPath As String) As Boolean
    Dim client As New MSXML2.XMLHTTP60
    
    On Error GoTo FallbackMethod1
    'redirects not supported with this method
    client.Open "GET", Url, False
    client.setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64)"
    client.send
    
    ' Check for success and save byte array to file
    If client.Status = 200 Then
        saveByteArrayToFile client.ResponseBody, fileFullPath
        downloadToFile = True: Exit Function
    End If
    
FallbackMethod1:
    'redirects supported here
    Dim client2 As New MSXML2.ServerXMLHTTP60
    
    On Error GoTo FallbackMethod2
    client2.Open "GET", Url, False
    client2.setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64)"
    client2.send
        
    ' Check for success and save byte array to file
    If client2.Status = 200 Then
        Debug.Print "ServerXMLHTTP60 fallback used for: " & Url
        saveByteArrayToFile client2.ResponseBody, fileFullPath
        downloadToFile = True: Exit Function
    End If
    
FallbackMethod2:
    On Error GoTo 0
    Debug.Print "UrlDownloadToFile fallback used for: " & Url
    downloadToFile = (UrlDownloadToFile(0&, StrPtr(Url), StrPtr(fileFullPath), 0&, 0&) = 0)
End Function

Here is a test sub for your convenience:

Sub test_DownloadResource()
    Dim driver As SeleniumVBA.WebDriver
    Dim element As SeleniumVBA.WebElement
    Dim fso As New FileSystemObject

    Set driver = SeleniumVBA.New_WebDriver

    driver.StartEdge
    driver.OpenBrowser

    driver.ImplicitMaxWait = 2000

    'img element with only src attribute
    driver.NavigateTo "https://github.com/GCuser99/SeleniumVBA/wiki"
    Set element = driver.FindElement(By.CssSelector, "img[alt='SeleniumVBA'")
    element.DownloadResource ("src")
    Debug.Assert fso.FileExists(driver.ResolvePath("logo.png"))
    driver.DeleteFiles "logo.png"

    driver.CloseBrowser
    driver.Shutdown
End Sub

[hanamichi77777]

Thanks @GCuser99

I wonder why your Office network 1 does not like UrlDownloadToFile? Do you think it is a security policy?

If I use MSXML2.XMLHTTP60 in a My Office network1 environment, I will receive a message saying "This site's security certificate revocation information cannot be used. Do you want to continue?" and you can download it by simply setting it to "Yes."

However, when I use the urldownloadtofile in Windows API, I get no message and can't download it,

If there is a problem with the certificate in MSXML2.XMLHTTP60, it appears that the user can display a dialog and choose to continue
There are some PCs that can be downloaded using urldownloadtofile in My Office network 1 environment, and although the obvious cause is unknown, it can be assumed that it is related to the certificate

The code presented by GCuser99 will work.
Because of an interesting issue, I also had AI create a 100-line version of WinHttp.
I'd like to try it when I have time.
If this works, you can expect to operate it with WinHttp only.

[hanamichi77777]

I created the code with the help of copilot.
Although the code is long(199Lines), it uses the WinHttp API to solve the following problems:
・Apply IE proxy settings
・Ignore SSL certificate errors
・Handle redirect
The proxy information is retrieved from the Windows network settings, not from the IE UI, so there will be no impact even if IE is discontinued.
I think it will work in @6DiegoDiego9's environment, but please try it if you have time
I'll leave it up to @GCuser99 to decide whether to actually adopt this code.

It makes full use of the WinHttp API. In the future, the WinHttp API will also be required for WebSocket communication in order to support WebDriver BiDi.

The following code goes in the declaration section(83Lines)

' WinHTTP API declarations
Private Declare PtrSafe Function WinHttpGetIEProxyConfigForCurrentUser Lib "winhttp.dll" ( _
    ByRef pProxyConfig As WINHTTP_CURRENT_USER_IE_PROXY_CONFIG) As Long

Private Declare PtrSafe Function WinHttpOpen Lib "winhttp.dll" ( _
    ByVal pwszUserAgent As LongPtr, _
    ByVal dwAccessType As Long, _
    ByVal pwszProxyName As LongPtr, _
    ByVal pwszProxyBypass As LongPtr, _
    ByVal dwFlags As Long) As LongPtr
    
Private Declare PtrSafe Function WinHttpConnect Lib "winhttp.dll" ( _
    ByVal hSession As LongPtr, ByVal pswzServerName As LongPtr, _
    ByVal nServerPort As Long, ByVal dwReserved As Long) As LongPtr

Private Declare PtrSafe Function WinHttpOpenRequest Lib "winhttp.dll" ( _
    ByVal hConnect As LongPtr, ByVal pwszVerb As LongPtr, _
    ByVal pwszObjectName As LongPtr, ByVal pwszVersion As LongPtr, _
    ByVal pwszReferrer As LongPtr, ByVal ppwszAcceptTypes As LongPtr, _
    ByVal dwFlags As Long) As LongPtr

Private Declare PtrSafe Function WinHttpSendRequest Lib "winhttp.dll" ( _
    ByVal hRequest As LongPtr, ByVal pwszHeaders As LongPtr, _
    ByVal dwHeadersLength As Long, ByVal lpOptional As LongPtr, _
    ByVal dwOptionalLength As Long, ByVal dwTotalLength As Long, _
    ByVal dwContext As LongPtr) As Long

Private Declare PtrSafe Function WinHttpReceiveResponse Lib "winhttp.dll" ( _
    ByVal hRequest As LongPtr, ByVal lpReserved As LongPtr) As Long

Private Declare PtrSafe Function WinHttpQueryHeaders Lib "winhttp.dll" ( _
    ByVal hRequest As LongPtr, ByVal dwInfoLevel As Long, _
    ByVal pwszName As LongPtr, ByVal lpBuffer As LongPtr, _
    ByRef lpdwBufferLength As Long, ByRef lpdwIndex As Long) As Long

Private Declare PtrSafe Function WinHttpReadData Lib "winhttp.dll" ( _
    ByVal hRequest As LongPtr, ByVal lpBuffer As LongPtr, _
    ByVal dwNumberOfBytesToRead As Long, ByRef lpdwNumberOfBytesRead As Long) As Long

Private Declare PtrSafe Function WinHttpCloseHandle Lib "winhttp.dll" ( _
    ByVal hInternet As LongPtr) As Long

Private Declare PtrSafe Function WinHttpSetOption Lib "winhttp.dll" ( _
    ByVal hInternet As LongPtr, _
    ByVal dwOption As Long, _
    ByRef lpBuffer As Any, _
    ByVal dwBufferLength As Long) As Long

Private Declare PtrSafe Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" ( _
        ByRef Destination As Any, ByRef Source As Any, ByVal Length As LongPtr)

Private Declare PtrSafe Function GlobalFree Lib "kernel32" ( _
    ByVal hMem As LongPtr) As LongPtr

' WinHTTP structures
Private Type WINHTTP_PROXY_INFO
    dwAccessType As Long
    lpszProxy As LongPtr
    lpszProxyBypass As LongPtr
End Type

' WinHTTP constants
Private Const WINHTTP_ACCESS_TYPE_NO_PROXY As Long = 1
Private Const WINHTTP_ACCESS_TYPE_NAMED_PROXY As Long = 3
Private Const WINHTTP_FLAG_SECURE As Long = &H800000
Private Const WINHTTP_AUTOPROXY_AUTO_DETECT As Long = &H1
Private Const WINHTTP_AUTO_DETECT_TYPE_DHCP As Long = &H1
Private Const WINHTTP_AUTO_DETECT_TYPE_DNS_A As Long = &H2
Private Const WINHTTP_OPTION_SECURITY_FLAGS As Long = 31
Private Const WINHTTP_OPTION_PROXY As Long = 38
Private Const SECURITY_FLAG_IGNORE_UNKNOWN_CA As Long = &H100
Private Const SECURITY_FLAG_IGNORE_CERT_CN_INVALID As Long = &H1000
Private Const SECURITY_FLAG_IGNORE_CERT_DATE_INVALID As Long = &H200
Private Const SECURITY_FLAG_IGNORE_CERT_WRONG_USAGE As Long = &H2000
Private Const SECURITY_FLAG_IGNORE_ALL As Long = SECURITY_FLAG_IGNORE_UNKNOWN_CA Or _
                                                 SECURITY_FLAG_IGNORE_CERT_CN_INVALID Or _
                                                 SECURITY_FLAG_IGNORE_CERT_DATE_INVALID Or _
                                                 SECURITY_FLAG_IGNORE_CERT_WRONG_USAGE
Private Const WINHTTP_QUERY_STATUS_CODE As Long = 19
Private Const WINHTTP_QUERY_FLAG_NUMBER As Long = &H20000000
Private Const WINHTTP_QUERY_LOCATION As Long = 33
Private Type WINHTTP_CURRENT_USER_IE_PROXY_CONFIG
    fAutoDetect As Long
    lpszAutoConfigUrl As LongPtr
    lpszProxy As LongPtr
    lpszProxyBypass As LongPtr
End Type

The following code is the procedure(116Lines)

' Main function to download a file from a URL with redirect and proxy support
Public Function downloadToFile(ByVal Url As String, ByVal SavePath As String) As Boolean
    Dim hSession As LongPtr, hConnect As LongPtr, hRequest As LongPtr
    Dim proxyInfo As WINHTTP_PROXY_INFO
    Dim currentUrl As String: currentUrl = Url
    Dim redirectCount As Integer: redirectCount = 0
    Dim statusCode As Long, statusSize As Long
    Dim locationBuffer As String, locationSize As Long
    Dim protocol As String, hostName As String, urlPath As String, port As Long

    ' Open WinHTTP session
    hSession = WinHttpOpen(StrPtr("Downloader"), WINHTTP_ACCESS_TYPE_NO_PROXY, 0, 0, 0)
    If hSession = 0 Then Exit Function

    ' Apply IE proxy settings
    Dim ieProxy As WINHTTP_CURRENT_USER_IE_PROXY_CONFIG
    If WinHttpGetIEProxyConfigForCurrentUser(ieProxy) <> 0 Then
        If ieProxy.lpszProxy <> 0 Then
            proxyInfo.dwAccessType = WINHTTP_ACCESS_TYPE_NAMED_PROXY
            proxyInfo.lpszProxy = ieProxy.lpszProxy
            proxyInfo.lpszProxyBypass = ieProxy.lpszProxyBypass
            WinHttpSetOption hSession, WINHTTP_OPTION_PROXY, proxyInfo, LenB(proxyInfo)
        End If
    
        If ieProxy.lpszProxy <> 0 Then GlobalFree ieProxy.lpszProxy
        If ieProxy.lpszProxyBypass <> 0 Then GlobalFree ieProxy.lpszProxyBypass
        If ieProxy.lpszAutoConfigUrl <> 0 Then GlobalFree ieProxy.lpszAutoConfigUrl
    End If

    ' Handle up to 10 redirects
    Do While redirectCount < 10
        ParseUrl currentUrl, protocol, hostName, urlPath, port

        ' Connect to host
        hConnect = WinHttpConnect(hSession, StrPtr(hostName), port, 0)

        ' Open HTTP request
        hRequest = WinHttpOpenRequest(hConnect, StrPtr("GET"), StrPtr(urlPath), 0, 0, 0, IIf(protocol = "https", WINHTTP_FLAG_SECURE, 0))

        ' Ignore SSL certificate errors
        Dim securityFlags As Long
        securityFlags = SECURITY_FLAG_IGNORE_ALL
        WinHttpSetOption hRequest, WINHTTP_OPTION_SECURITY_FLAGS, securityFlags, LenB(securityFlags)

        ' Send and receive
        WinHttpSendRequest hRequest, 0, 0, 0, 0, 0, 0
        WinHttpReceiveResponse hRequest, 0

        ' Get HTTP status code
        statusSize = Len(statusCode)
        WinHttpQueryHeaders hRequest, WINHTTP_QUERY_STATUS_CODE Or WINHTTP_QUERY_FLAG_NUMBER, 0, VarPtr(statusCode), statusSize, 0

        ' Handle redirect
        If statusCode >= 300 And statusCode < 400 Then
            locationSize = 1024
            locationBuffer = String(512, 0)
            If WinHttpQueryHeaders(hRequest, WINHTTP_QUERY_LOCATION, 0, StrPtr(locationBuffer), locationSize, 0) <> 0 Then
                currentUrl = Left(locationBuffer, InStr(locationBuffer, vbNullChar) - 1)
                WinHttpCloseHandle hRequest
                WinHttpCloseHandle hConnect
                redirectCount = redirectCount + 1
            Else
                Exit Do
            End If
        ElseIf statusCode = 200 Then
            Exit Do
        Else
            Exit Function
        End If
    Loop

    ' Download response body
    Dim binaryStream As New ADODB.Stream
    binaryStream.Type = 1 ' Binary
    binaryStream.Open

    Dim pData() As Byte: ReDim pData(8191)
    Dim dwDownloaded As Long

    Do
        If WinHttpReadData(hRequest, VarPtr(pData(0)), 8192, dwDownloaded) = 0 Then Exit Do
        If dwDownloaded = 0 Then Exit Do
        
        Dim actualData() As Byte
        ReDim actualData(dwDownloaded - 1)
        CopyMemory actualData(0), pData(0), dwDownloaded
        binaryStream.Write actualData
    Loop

    ' Save to file
    binaryStream.SaveToFile SavePath, 2 ' Overwrite if exists
    binaryStream.Close

    ' Clean up
    WinHttpCloseHandle hRequest
    WinHttpCloseHandle hConnect
    WinHttpCloseHandle hSession

    downloadToFile = True
End Function

' Parse URL into protocol, host, path, and port
Private Sub ParseUrl(ByVal Url As String, ByRef protocol As String, ByRef hostName As String, ByRef urlPath As String, ByRef port As Long)
    Dim pos As Long
    pos = InStr(Url, "://")
    protocol = Left(Url, pos - 1)
    Url = Mid(Url, pos + 3)
    pos = InStr(Url, "/")
    If pos > 0 Then
        hostName = Left(Url, pos - 1)
        urlPath = Mid(Url, pos)
    Else
        hostName = Url
        urlPath = "/"
    End If
    If protocol = "https" Then
        port = 443
    Else: port = 80
    End If
End Sub

(10/6/2025)
Binary data corruption discovered and fixed.
Note that the WinHttp API cannot use the ResponseBody property, so it was not possible to replace it with the saveByteArrayToFile method.

[hanamichi77777]

I was wondering how to get the proxy settings, but copilot's answer is as follows

Why is WinHttpGetIEProxyConfigForCurrentUser the only one that works?
🧠 Here's why:
It’s the only WinHTTP function that can directly access Internet Explorer’s proxy settings.
Other functions, like WinHttpGetProxyForUrl, depend on environments where PAC files or WPAD are available, and they can fail if those aren’t properly configured.
WinHttpGetIEProxyConfigForCurrentUser is specifically designed to retrieve the current user's IE proxy settings, making it a reliable fallback.
In short, while other functions help you use a proxy for communication, they don’t tell you which proxy to use.
So if you just want to grab the proxy settings, this function is your best bet!

[GCuser99]

@hanamichi77777, thanks for the code suggestion and all of your testing - very excellent.

I took your code and asked Claude AI to simplify it (while honoring functionality) using a hybrid approach with WinHttp.WinHttpRequest.5.1 and proxy related API. Below is what was produced after a couple of iterations (<80 lines). Provided this still works in all of your environments, and it does not break in @6DiegoDiego9's and anyone else's who is paying attention, and does not significantly increase our Total Virus score, then I'm ok with replacing UrlDownloadToFile with this "lite" version.

'WinDevLib declares
Private Declare PtrSafe Function WinHttpGetIEProxyConfigForCurrentUser Lib "winhttp.dll" (ByRef pProxyConfig As WINHTTP_CURRENT_USER_IE_PROXY_CONFIG) As Long
Private Declare PtrSafe Function GlobalFree Lib "kernel32" (ByVal hMem As LongPtr) As LongPtr
Private Declare PtrSafe Function lstrlenW Lib "kernel32" (lpString As Any) As Long
Private Declare PtrSafe Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As LongPtr)

Private Type WINHTTP_CURRENT_USER_IE_PROXY_CONFIG
    fAutoDetect As Long
    lpszAutoConfigUrl As LongPtr
    lpszProxy As LongPtr
    lpszProxyBypass As LongPtr
End Type

Private Const HTTPREQUEST_PROXYSETTING_PROXY As Long = 2

' Convert pointer to string
Private Function ptrToStr(ByVal lpsz As LongPtr) As String
    Dim Length As Long
    If lpsz = 0 Then Exit Function
    Length = lstrlenW(ByVal lpsz)
    If Length > 0 Then
        ptrToStr = Space$(Length)
        CopyMemory ByVal StrPtr(ptrToStr), ByVal lpsz, Length * 2 ' Unicode = 2 bytes/char
    End If
End Function

Public Function downloadToFile(ByVal Url As String, ByVal filePath As String) As Boolean
    Dim http As Object
    Dim bytes() As Byte
    Dim ieProxy As WINHTTP_CURRENT_USER_IE_PROXY_CONFIG
    
    On Error GoTo ErrHandler
    
    Set http = CreateObject("WinHttp.WinHttpRequest.5.1")
    
    http.setTimeouts 15000, 15000, 15000, 15000
    
    ' Apply IE proxy settings if found
    If WinHttpGetIEProxyConfigForCurrentUser(ieProxy) <> 0 Then
        If ieProxy.lpszProxy <> 0 Then
            Dim proxyStr As String
            proxyStr = ptrToStr(ieProxy.lpszProxy)
            Dim bypassStr As String
            If ieProxy.lpszProxyBypass <> 0 Then bypassStr = ptrToStr(ieProxy.lpszProxyBypass)
            http.setProxy HTTPREQUEST_PROXYSETTING_PROXY, proxyStr, bypassStr
        End If
        ' Free allocated strings
        If ieProxy.lpszProxy <> 0 Then GlobalFree ieProxy.lpszProxy
        If ieProxy.lpszProxyBypass <> 0 Then GlobalFree ieProxy.lpszProxyBypass
        If ieProxy.lpszAutoConfigUrl <> 0 Then GlobalFree ieProxy.lpszAutoConfigUrl
    End If
    
    ' Send request
    http.Open "GET", Url, False
    http.setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64)"
    http.send
    
    ' Check status and save response to file
    If http.Status >= 200 And http.Status < 300 Then
        bytes = http.ResponseBody
        saveByteArrayToFile bytes, filePath
        downloadToFile = True
    Else
        Debug.Print "HTTP error: " & http.Status
    End If
    
    Exit Function
    
ErrHandler:
    Debug.Print "Error: " & Err.Description
End Function

[GCuser99]

@hanamichi77777, if the code above does not work for your corporate environments, please try by commenting out the following line:

http.setProxy 0 ' HTTPREQUEST_PROXYSETTING_DEFAULT (WinHTTP default) = 0

Otherwise, I believe it should replicate your pure api version exactly.

[hanamichi77777]

Great!!
I had never thought of a hybrid of WinHttp.WinHttpRequest.5.1 and WinHttp API functions.
The code presented by @GCuser99 works perfectly in my environment. If it works in @6DiegoDiego9's environment, it would be perfect.

[hanamichi77777]

I was concerned about security issues with ignore all common SSL errors.

However, in My Office (network1), I can download using the a hybrid
even if I delete "http.Option(4) = &H3300".

On the other hand, I tried three times but can't download using the UrlDownloadToFile,
It doesn't seem to be due to a certificate error.

I recommend removing "http.Option(4) = &H3300".
Thank you for a very interesting topic!

[GCuser99]

Awesome - thanks for checking! If/when you have time, can you also try it with the following line commented out?

http.setProxy 0 ' HTTPREQUEST_PROXYSETTING_DEFAULT (WinHTTP default) = 0

[hanamichi77777]

OK, please wait 10 hours.

[hanamichi77777]

Sorry to keep you waiting.
Commenting out the code below works in all my environments.
Thank you.

can you also try it with the following line commented out?

http.setProxy 0 ' HTTPREQUEST_PROXYSETTING_DEFAULT (WinHTTP default) = 0

[GCuser99]

No problem and thanks! I edited the hybrid version of your code above to take that line out. It is also not necessary to enable the redirects as that is enabled by default. I changed the CopyMemory declaration to be compatible with WinDevLib, which I use on all API declarations in the twinBASIC DLL project.

Anyway, it's now a fairly standard WinHttp downloader, but with the addition of @hanamichi77777's proxy stuff. It solves an issue on one of @hanamichi77777's corporate networks that does not seem to allow UrlDownloadToFile. @6DiegoDiego9, what do you think of this as a replacement for UrlDownloadToFile?

While we wait to hear back from Diego, I'll do a VirusTotal check to see how the replacement compares on false-positives.

[hanamichi77777]

If WinHttp.WinHttpRequest.5.1 is enabled for Defender, you may want to consider replacing MSXML2.ServerXMLHTTP60, which you use to communicate with WebDriver, with WinHttp.WinHttpRequest.5.1.

Since it's a local connection with WebDriver,
WinHttp.WinHttpRequest.5.1 works in all environments, including my proxy environment, without WinHttpGetIEProxyConfigForCurrentUser.

’ClassModule WebDriver
'Reference Miscosoft WinHTTP Services, version 5.1

Friend Function execute(driverCommand As Variant, Optional parameters As Dictionary = Nothing, Optional ByVal raiseError As Boolean = True, Optional ByVal receiveTimeout As Long = -1) As Dictionary
    
  Dim client As New WinHttp.WinHttpRequest

[hanamichi77777]

Since the requestData Function of ClassModule WebDriverManager is connected to the Internet, it seems better to continue using MSXML2.XMLHTTP60 or using hybrid.

Private Function requestData(ByVal Url As String, Optional maxTries As Long = 20) As Variant
 'see https://github.com/GCuser99/SeleniumVBA/discussions/29#discussioncomment-3673682
 
 Dim client As New MSXML2.XMLHTTP60

[6DiegoDiego9]

Here are my test results:

Home PC:

URLDownloadToFile: success
WinHttp 200 lines: success
WinHttp 80 lines: success

Business PC:

URLDownloadToFile: success
WinHttp 200 lines: fails
WinHttp 80 lines: fails with "Name or server address could not be resolved"

[hanamichi77777]

Code using low level WinINet based API.
It uses the same WinINet as URLDownloadToFile.

Redirection is supported by default
This code is also likely to work with @6DiegoDiego9

Since it is a code that is not used much, I think it is unlikely that it will be falsely detected by Defender.
I'll check now to see if it works with my Business network

P.S.
It worked in all my environments.
I hope it works in @6DiegoDiego9 environment too.
In my environment, a certificate error (12057) sometimes occurs in Chrome, so I followed the steps at the end.
（However, UrlDownKoadToFile does not know the error number.）
Following the AI's advice, I have changed the buffer size to 8KB.
I replaced CopyMemory because it is prone to false positives.

I thought about whether I could solve this using the WinHttp API, but I couldn't find a generic solution.

' WinINet API declarations
Private Declare PtrSafe Function InternetOpen Lib "wininet.dll" Alias "InternetOpenA" ( _
    ByVal sAgent As String, ByVal lAccessType As Long, _
    ByVal sProxyName As String, ByVal sProxyBypass As String, _
    ByVal lFlags As Long) As LongPtr
Private Declare PtrSafe Function InternetOpenUrl Lib "wininet.dll" Alias "InternetOpenUrlA" ( _
    ByVal hInternetSession As LongPtr, ByVal sUrl As String, _
    ByVal sHeaders As String, ByVal lHeadersLength As Long, _
    ByVal lFlags As Long, ByVal lContext As LongPtr) As LongPtr
Private Declare PtrSafe Function InternetReadFile Lib "wininet.dll" ( _
    ByVal hFile As LongPtr, ByVal sBuffer As LongPtr, _
    ByVal lNumBytesToRead As Long, lNumBytesRead As Long) As Long
Private Declare PtrSafe Function InternetCloseHandle Lib "wininet.dll" ( _
    ByVal hInet As LongPtr) As Long

' Main function to download a file using WinINet
Public Function downloadToFile(ByVal Url As String, ByVal fileFullPath As String) As Boolean
    Const BUFFER_SIZE As Long = 8192
    Const INTERNET_OPEN_TYPE_PRECONFIG As Long = 0
    Const INTERNET_FLAG_RELOAD As Long = &H80000000
    Const INTERNET_FLAG_NO_CACHE_WRITE As Long = &H4000000
    Const INTERNET_FLAGS As Long = INTERNET_FLAG_RELOAD
    
    Dim hInternet As LongPtr
    Dim hUrl As LongPtr
    Dim bBuffer() As Byte
    Dim lBytesRead As Long
    Dim fileNum As Integer
    Dim filePos As Long
    
    downloadToFile = False
    
    ' Initialize WinINet session using system proxy settings (PAC included)
    hInternet = InternetOpen("Mozilla/5.0 (Windows NT 10.0; Win64; x64)", INTERNET_OPEN_TYPE_PRECONFIG, vbNullString, vbNullString, 0)
    If hInternet = 0 Then
        MsgBox "InternetOpen failed. Error code: " & Err.LastDllError, vbCritical, "WinInet API"
        Exit Function
    End If
    
    ' Open the URL (PAC evaluation happens automatically if configured)
    hUrl = InternetOpenUrl(hInternet, Url, vbNullString, 0, INTERNET_FLAGS, 0)
    If hUrl = 0 Then
        MsgBox "InternetOpenUrl failed. Error code: " & Err.LastDllError, vbCritical, "WinInet API"
        InternetCloseHandle hInternet
        Exit Function
    End If
    
    ' Prepare to write to file
    fileNum = FreeFile
    Open fileFullPath For Binary Access Write As #fileNum
    
    ReDim bBuffer(BUFFER_SIZE - 1)
    filePos = 1
    
    ' Read and write data in chunks
    Do
        If InternetReadFile(hUrl, VarPtr(bBuffer(0)), BUFFER_SIZE, lBytesRead) = 0 Then
            MsgBox "InternetReadFile failed. Error code: " & Err.LastDllError, vbCritical, "WinInet API"
            Exit Do
        End If
        
        If lBytesRead = 0 Then Exit Do
        
        ' Copy the actual bytes read into a temporary buffer
        Dim tempBuffer() As Byte
        ReDim tempBuffer(lBytesRead - 1)
        Dim i As Long
        For i = 0 To lBytesRead - 1
            tempBuffer(i) = bBuffer(i)
        Next i
        
        ' Write the buffer to file
        Put #fileNum, filePos, tempBuffer
        filePos = filePos + lBytesRead
    Loop
    
    ' Clean up
    Close #fileNum
    InternetCloseHandle hUrl
    InternetCloseHandle hInternet
    
    downloadToFile = True
End Function

Fixing Certificate Error 12057 via Internet Options
Right-click the Start button → Click “Settings” → Go to “Network & Internet” → Scroll down and click “Internet Options” → Click the “Advanced” tab → Scroll to the “Security” section → Uncheck “Check for server certificate revocation” → Click “Apply” and then “OK” → Restart your browser or computer.
https://dorocosoft.sakura.ne.jp/faq/faq_wininet_error_12057.htm

[GCuser99]

Here is an extension of the winhttp hybrid that supposedly handles auto-proxy for PAC and WPAD but of course I have no way of testing this on my local machine. It is <140 lines.

But honestly, I'll let you guys decide since you can test under a number of different network situations.

Private Declare PtrSafe Function WinHttpGetProxyForUrl Lib "winhttp" (ByVal hSession As LongPtr, ByVal lpcwszUrl As LongPtr, pAutoProxyOptions As WINHTTP_AUTOPROXY_OPTIONS, pProxyInfo As WINHTTP_PROXY_INFO) As Long
Private Declare PtrSafe Function WinHttpOpen Lib "winhttp" (ByVal pszAgentW As LongPtr, ByVal dwAccessType As Long, ByVal pszProxyW As LongPtr, ByVal pszProxyBypassW As LongPtr, ByVal dwFlags As Long) As LongPtr
Private Declare PtrSafe Function WinHttpCloseHandle Lib "winhttp" (ByVal hInternet As LongPtr) As Long
Private Declare PtrSafe Function WinHttpGetIEProxyConfigForCurrentUser Lib "winhttp.dll" (ByRef pProxyConfig As WINHTTP_CURRENT_USER_IE_PROXY_CONFIG) As Long
Private Declare PtrSafe Function GlobalFree Lib "kernel32" (ByVal hMem As LongPtr) As LongPtr
Private Declare PtrSafe Function lstrlenW Lib "kernel32" (lpString As Any) As Long
Private Declare PtrSafe Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As LongPtr)
      
Private Type WINHTTP_AUTOPROXY_OPTIONS
    dwFlags As Long
    dwAutoDetectFlags As Long
    lpszAutoConfigUrl As LongPtr
    lpvReserved As LongPtr
    dwReserved As Long
    fAutoLogonIfChallenged As Long
End Type

Private Type WINHTTP_PROXY_INFO
    dwAccessType As Long
    lpszProxy As LongPtr
    lpszProxyBypass As LongPtr
End Type

Private Type WINHTTP_CURRENT_USER_IE_PROXY_CONFIG
    fAutoDetect As Long
    lpszAutoConfigUrl As LongPtr
    lpszProxy As LongPtr
    lpszProxyBypass As LongPtr
End Type

Private Const WINHTTP_AUTOPROXY_AUTO_DETECT As Long = &H1
Private Const WINHTTP_AUTOPROXY_CONFIG_URL As Long = &H2
Private Const WINHTTP_AUTO_DETECT_TYPE_DHCP As Long = &H1
Private Const WINHTTP_AUTO_DETECT_TYPE_DNS_A As Long = &H2
Private Const WINHTTP_ACCESS_TYPE_NO_PROXY As Long = 1

Private Const HTTPREQUEST_PROXYSETTING_PROXY As Long = 2

' Convert pointer to string
Private Function ptrToStr(ByVal lpsz As LongPtr) As String
    Dim Length As Long
    If lpsz = 0 Then Exit Function
    Length = lstrlenW(ByVal lpsz)
    If Length > 0 Then
        ptrToStr = Space$(Length)
        CopyMemory ByVal StrPtr(ptrToStr), ByVal lpsz, Length * 2 ' Unicode = 2 bytes/char
    End If
End Function

Public Function downloadToFile(ByVal Url As String, ByVal filePath As String) As Boolean
    Dim http As Object
    Dim bytes() As Byte
    Dim ieProxy As WINHTTP_CURRENT_USER_IE_PROXY_CONFIG
    Dim autoProxyOptions As WINHTTP_AUTOPROXY_OPTIONS
    Dim proxyInfo As WINHTTP_PROXY_INFO
    Dim hSession As LongPtr
    Dim proxyStr As String
    Dim bypassStr As String
    
    On Error GoTo ErrHandler
    
    Set http = CreateObject("WinHttp.WinHttpRequest.5.1")
    http.setTimeouts 15000, 15000, 15000, 15000
    http.Option(4) = &H3300  ' Ignore common SSL errors (Optional)
    
    ' Try IE proxy settings first
    If WinHttpGetIEProxyConfigForCurrentUser(ieProxy) <> 0 Then
        
        ' Handle static proxy
        If ieProxy.lpszProxy <> 0 Then
            proxyStr = ptrToStr(ieProxy.lpszProxy)
            If ieProxy.lpszProxyBypass <> 0 Then bypassStr = ptrToStr(ieProxy.lpszProxyBypass)
            http.setProxy HTTPREQUEST_PROXYSETTING_PROXY, proxyStr, bypassStr
            GoTo ProxyConfigured
        End If
        
        ' Handle PAC file or auto-detect
        If ieProxy.lpszAutoConfigUrl <> 0 Or ieProxy.fAutoDetect <> 0 Then
            hSession = WinHttpOpen(0, WINHTTP_ACCESS_TYPE_NO_PROXY, 0, 0, 0)
            
            If hSession <> 0 Then
                ' Configure auto-proxy options
                If ieProxy.fAutoDetect <> 0 Then
                    autoProxyOptions.dwFlags = WINHTTP_AUTOPROXY_AUTO_DETECT
                    autoProxyOptions.dwAutoDetectFlags = WINHTTP_AUTO_DETECT_TYPE_DHCP Or WINHTTP_AUTO_DETECT_TYPE_DNS_A
                End If
                
                If ieProxy.lpszAutoConfigUrl <> 0 Then
                    autoProxyOptions.dwFlags = autoProxyOptions.dwFlags Or WINHTTP_AUTOPROXY_CONFIG_URL
                    autoProxyOptions.lpszAutoConfigUrl = ieProxy.lpszAutoConfigUrl
                End If
                
                autoProxyOptions.fAutoLogonIfChallenged = 1
                
                ' Get proxy for this specific URL
                If WinHttpGetProxyForUrl(hSession, StrPtr(Url), autoProxyOptions, proxyInfo) <> 0 Then
                    If proxyInfo.lpszProxy <> 0 Then
                        proxyStr = ptrToStr(proxyInfo.lpszProxy)
                        If proxyInfo.lpszProxyBypass <> 0 Then bypassStr = ptrToStr(proxyInfo.lpszProxyBypass)
                        http.setProxy HTTPREQUEST_PROXYSETTING_PROXY, proxyStr, bypassStr
                        
                        ' Free proxy info strings
                        If proxyInfo.lpszProxy <> 0 Then GlobalFree proxyInfo.lpszProxy
                        If proxyInfo.lpszProxyBypass <> 0 Then GlobalFree proxyInfo.lpszProxyBypass
                    End If
                End If
                
                WinHttpCloseHandle hSession
            End If
        End If
        
ProxyConfigured:
        ' Free IE proxy config strings
        If ieProxy.lpszProxy <> 0 Then GlobalFree ieProxy.lpszProxy
        If ieProxy.lpszProxyBypass <> 0 Then GlobalFree ieProxy.lpszProxyBypass
        If ieProxy.lpszAutoConfigUrl <> 0 Then GlobalFree ieProxy.lpszAutoConfigUrl
    End If
    
    ' Send request
    http.Open "GET", Url, False
    http.setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64)"
    http.send
    
    ' Check status and save response to file
    If http.Status >= 200 And http.Status < 300 Then
        bytes = http.ResponseBody
        saveByteArrayToFile bytes, filePath
        downloadToFile = True
    Else
        Debug.Print "HTTP error: " & http.Status
    End If
    
    Exit Function
    
ErrHandler:
    Debug.Print "Error: " & Err.Description
End Function

[hanamichi77777]

Thank you.
I will check it in a proxy environment.

[hanamichi77777]

The code @GCuser99 provided worked in all of my proxy environments.
I hope the false positives are resolved as soon as possible.

[hanamichi77777]

I created this using Copilot to meet all four of the following conditions.
It's 132 lines long. It works fine in my environment.
I'm providing it for your consideration.

✅ Condition Check
① Avoid using UrlDownloadToFile
Status: ✅ Fulfilled
Details: The code does not use UrlDownloadToFile. Instead, it uses direct WinINet API calls (InternetOpen, InternetConnect, HttpOpenRequest, HttpSendRequest, InternetReadFile), which helps avoid false positives from Windows Defender.

② Achieve proxy connectivity equivalent to UrlDownloadToFile
Status: ✅ Fulfilled
Details: The use of INTERNET_OPEN_TYPE_PRECONFIG in InternetOpen ensures that the system's proxy settings (including automatic proxy configuration) are respected, just like UrlDownloadToFile.

③ Support redirects equivalent to HttpRequest
Status: ✅ Fulfilled
Details: The code checks the HTTP status code using HttpQueryInfo and follows redirects by recursively calling downloadToFile when a 3xx status is detected. It supports up to 5 redirects.

④ Handle certificate errors equivalent to HttpRequest
Status: ✅ Fulfilled
Details: The code sets flags such as INTERNET_FLAG_IGNORE_CERT_CN_INVALID, INTERNET_FLAG_IGNORE_CERT_DATE_INVALID, and SECURITY_FLAG_IGNORE_REVOCATION to bypass common certificate errors, including revocation checks (error 12057).

' === WinINet API declarations (for 64-bit VBA only) ===
Private Declare PtrSafe Function InternetOpen Lib "wininet.dll" Alias "InternetOpenA" ( _
    ByVal sAgent As String, ByVal lAccessType As Long, _
    ByVal sProxyName As String, ByVal sProxyBypass As String, _
    ByVal lFlags As Long) As LongPtr
Private Declare PtrSafe Function InternetConnect Lib "wininet.dll" Alias "InternetConnectA" ( _
    ByVal hInternetSession As LongPtr, ByVal lpszServerName As String, _
    ByVal nServerPort As Long, ByVal lpszUserName As String, _
    ByVal lpszPassword As String, ByVal dwService As Long, _
    ByVal dwFlags As Long, ByVal dwContext As LongPtr) As LongPtr
Private Declare PtrSafe Function HttpOpenRequest Lib "wininet.dll" Alias "HttpOpenRequestA" ( _
    ByVal hConnect As LongPtr, ByVal lpszVerb As String, _
    ByVal lpszObjectName As String, ByVal lpszVersion As String, _
    ByVal lpszReferrer As String, ByVal lplpszAcceptTypes As LongPtr, _
    ByVal dwFlags As Long, ByVal dwContext As LongPtr) As LongPtr
Private Declare PtrSafe Function InternetSetOption Lib "wininet.dll" Alias "InternetSetOptionA" ( _
    ByVal hInternet As LongPtr, ByVal dwOption As Long, _
    ByVal lpBuffer As LongPtr, ByVal dwBufferLength As Long) As Long
Private Declare PtrSafe Function HttpSendRequest Lib "wininet.dll" Alias "HttpSendRequestA" ( _
    ByVal hRequest As LongPtr, ByVal sHeaders As String, _
    ByVal lHeadersLength As Long, ByVal lpOptional As LongPtr, _
    ByVal lOptionalLength As Long) As Long
Private Declare PtrSafe Function InternetReadFile Lib "wininet.dll" ( _
    ByVal hFile As LongPtr, ByVal lpBuffer As LongPtr, _
    ByVal dwNumberOfBytesToRead As Long, _
    lNumberOfBytesRead As Long) As Long
Private Declare PtrSafe Function InternetCloseHandle Lib "wininet.dll" ( _
    ByVal hInternet As LongPtr) As Long
Private Declare PtrSafe Function HttpQueryInfo Lib "wininet.dll" Alias "HttpQueryInfoA" ( _
    ByVal hRequest As LongPtr, ByVal dwInfoLevel As Long, _
    ByVal lpBuffer As Any, lpdwBufferLength As Long, _
    lpdwIndex As Long) As Long

' === Constants ===
Private Const INTERNET_OPEN_TYPE_PRECONFIG = 0
Private Const INTERNET_SERVICE_HTTPS = 3
Private Const INTERNET_FLAG_SECURE = &H800000
Private Const INTERNET_FLAG_RELOAD = &H80000000
Private Const INTERNET_FLAG_IGNORE_CERT_CN_INVALID = &H1000
Private Const INTERNET_FLAG_IGNORE_CERT_DATE_INVALID = &H2000
Private Const INTERNET_OPTION_SECURITY_FLAGS = 31
Private Const SECURITY_FLAG_IGNORE_REVOCATION = &H80
Private Const HTTP_QUERY_STATUS_CODE = 19
Private Const HTTP_QUERY_LOCATION = 33

' === File download function with redirect support ===
Public Function downloadToFile(ByVal url As String, ByVal filePath As String) As Boolean
    Const MAX_REDIRECTS As Long = 5
    Dim redirectCount As Long

    Dim server As String, objectPath As String, port As Long
    Dim hInternet As LongPtr, hConnect As LongPtr, hRequest As LongPtr
    Dim flags As Long, result As Long, secFlags As Long
    Dim statusCode As String * 4, statusLen As Long
    Dim location As String * 2048, locLen As Long
    Dim buffer(0 To 8191) As Byte, bytesRead As Long, fileNum As Long
    Dim tempBuffer() As Byte
    Dim i As Long

    Do
        If redirectCount > MAX_REDIRECTS Then Exit Function
        redirectCount = redirectCount + 1

        If Not ParseUrl(url, server, objectPath, port) Then Exit Function

        hInternet = InternetOpen("Mozilla/5.0 (Windows NT 10.0; Win64; x64)", INTERNET_OPEN_TYPE_PRECONFIG, vbNullString, vbNullString, 0)
        If hInternet = 0 Then Exit Function

        hConnect = InternetConnect(hInternet, server, port, vbNullString, vbNullString, INTERNET_SERVICE_HTTPS, 0, 0)
        If hConnect = 0 Then GoTo Cleanup

        flags = INTERNET_FLAG_SECURE Or INTERNET_FLAG_RELOAD Or INTERNET_FLAG_IGNORE_CERT_CN_INVALID Or INTERNET_FLAG_IGNORE_CERT_DATE_INVALID
        hRequest = HttpOpenRequest(hConnect, "GET", objectPath, "HTTP/1.1", vbNullString, 0, flags, 0)
        If hRequest = 0 Then GoTo Cleanup

        secFlags = SECURITY_FLAG_IGNORE_REVOCATION
        Call InternetSetOption(hRequest, INTERNET_OPTION_SECURITY_FLAGS, VarPtr(secFlags), LenB(secFlags))

        result = HttpSendRequest(hRequest, vbNullString, 0, 0, 0)
        If result = 0 Then GoTo Cleanup

        ' Check HTTP status code
        statusLen = Len(statusCode)
        If HttpQueryInfo(hRequest, HTTP_QUERY_STATUS_CODE, ByVal statusCode, statusLen, 0) <> 0 Then
            If Left$(statusCode, 1) = "3" Then
                ' Get redirect location
                locLen = Len(location)
                If HttpQueryInfo(hRequest, HTTP_QUERY_LOCATION, ByVal location, locLen, 0) <> 0 Then
                    url = Left$(location, locLen)
                    If hRequest <> 0 Then InternetCloseHandle hRequest
                    If hConnect <> 0 Then InternetCloseHandle hConnect
                    If hInternet <> 0 Then InternetCloseHandle hInternet
                    GoTo NextRedirect
                End If
            End If
        End If

        ' Open file for binary write
        fileNum = FreeFile
        Open filePath For Binary Access Write As #fileNum
        Do
            result = InternetReadFile(hRequest, VarPtr(buffer(0)), UBound(buffer) + 1, bytesRead)
            If result = 0 Or bytesRead = 0 Then Exit Do

            ' Resize temporary buffer to actual bytes read
            ReDim tempBuffer(0 To bytesRead - 1)
            For i = 0 To bytesRead - 1
                tempBuffer(i) = buffer(i)
            Next i

            ' Write only the valid portion of buffer
            Put #fileNum, , tempBuffer
        Loop
        Close #fileNum

        downloadToFile = True

Cleanup:
        If hRequest <> 0 Then InternetCloseHandle hRequest
        If hConnect <> 0 Then InternetCloseHandle hConnect
        If hInternet <> 0 Then InternetCloseHandle hInternet
        Exit Do

NextRedirect:
        ' Continue loop
    Loop
End Function

' === Parse URL into host, path, and port ===
Private Function ParseUrl(ByVal fullUrl As String, ByRef server As String, ByRef objectPath As String, ByRef port As Long) As Boolean
    Dim s As String: s = Replace(fullUrl, "https://", "")
    Dim p As Long: p = InStr(s, "/")
    If p = 0 Then Exit Function
    server = Left(s, p - 1)
    objectPath = Mid(s, p)
    port = 443
    ParseUrl = True
End Function

[6DiegoDiego9]

Thanks guys for your efforts!
I think I'll be able to try it in all my environments within 3 days.
After that, if all will pass, I'm fine with any <150 lines solutions.

[6DiegoDiego9]

Good news!

I finally tested both on your last solutions on all my 4 environments, using a test module with 7 test cases generated by Sonnet-4.5-high.

More specifically:

1. Simple direct download - Basic HTTPS file download
2. Redirect download - Following HTTP 3xx redirects
3. Invalid URL handling - Non-existent domain
4. Invalid file path handling - Bad file system path
5. Large file download - Performance testing
6. Different file types - Multiple content types (PNG, JPEG, HTML)
7. 404 error handling - HTTP error response

You can download and run my test here. Just switch the access modifier (Private/Public) of the function DownloadToFile in either the GCuser99 or hanamichi77777 module, depending on which one you want to test, and launch Tests.TestDownloadToFile, which calls the only DownloadToFile left Public.

Results:

GCuser99 solution:
All passed with 7/7 (one initially passed with 6/7, but on the second try it passed with 7/7)
VirusTotal report:

hanamichi77777 solution:
All passed with 7/7
VirusTotal report:

Note: WinINet seems discouraged, being closely tied to now-deprecated Internet Explorer (see https://www.perplexity.ai/search/is-wininet-deprecated-by-micro-XEJSkuUXRLaqcTPQY.cM_g#0)

My final though, considering the 7/7 passes (tie), the VirusTotal reports (hanamichi77777 wins), and the fact that WinINet is discouraged (GCuser99 wins), is that I'm fine with both solutions, with no preference.

[hanamichi77777]

Thank you very much for the very interesting experiment.
I'm happy that @6DiegoDiego9 can connect BusinessPC with @GCuser99's code.
I recommend using the WinHttpRequest.5.1+ WinHttp API.

[GCuser99]

@6DiegoDiego9 thanks for the test suite! For a base case compare, I also added a test suite for UrlToDownloadFile API. I am not on a business pc and I'm getting very strange and inconsistent results for each test - fail/pass, sometimes long delays, and sometimes garbage download results. I'm going to have to take a closer look to see what is going on with my system!

[GCuser99]

Oh, it looks like there is currently a problem with https://httpbin.org (503 Service Temporarily Unavailable). What is interesting is that WinInet version passes all the tests with that website down but the downloads are (of course) garbage.

[6DiegoDiego9]

I see like this now

[GCuser99]

Maybe my IP address is blocked. Using a VPN seems to have corrected the situation for now. The base case API fails on bad url test. One thing I noticed Is that the WinInet version, even though it passes the redirect test, the test_redirect.png result is not readable - anyone else see this?

[6DiegoDiego9]

Down for me now too:

This is what I get with your solution (8 KB):

while with hanamichi77777’s solution, I get a 162-byte unreadable file.

I think we can now all agree on implementing your solution in the WebShared module.

[hanamichi77777]

Occasional Certificate Errors occurred when using UrlDownLoadToFile or WinInetAPI on NetWork1.
But @GCuser99's solution doesn't cause them.
I agree on implementing @GCuser99's solution in the WebShared module.

Date	SeleniumVBA Version	Win Defender	Virus Total Score
10/16/25	SeleniumVBA.xlsm ver.6.7 test1 +WinHttpRequest +WinHttpAPI(140Lines)	No Detection 1.439.195.0	4/65

[GCuser99]

Great teamwork @6DiegoDiego9 and @hanamichi77777 - thanks!

[hanamichi77777]

On My Business NetWork1, even if I comment out the following code, I don't get a certificate error.
The reason seems to be as follows:

http.Option(4) = &H3300  ' Ignore common SSL errors (Optional)

I recommend commenting it out to reduce the risk of false positives.

[hanamichi77777]

Unfortunately, a false positive was caused by Defender.
The contents are as follows.
I'm surprised that test1 isn't detected.

Date	SeleniumVBA Version	Win Defender	Virus Total Score
10/19/25	SeleniumVBA.xlsm ver.6.7 test1	No Detection 1.439.290.0	4/65
10/19/25	SeleniumVBA.xlsm ver.6.7 test1 +WinHttpRequest +WinHttpAPI(140Lines)	Detection 1.439.290.0	4/65
10/19/25	SeleniumVBA.xlsm ver.6.7 test9	Detection 1.439.290.0	4/65

The Defender message is as follows.

Copilot's message is as follows.

[6DiegoDiego9]

Can you please remind me what test1 is?

[hanamichi77777]

test1 is as follows.
However, it may be detected depending on the version of Defender.

[hanamichi77777]

Linking files to GitHub might raise some concerns.
The following files will be detected as false positives by Defender.
SeleniumVBA.xlsm ver.6.7 test1 +WinHttpRequest +WinHttpAPI(140Lines)

Although it is the same code, it is a newly created file, so there will be no false positives.
SeleniumVBA.xlsm ver.6.7 test1 +WinHttpRequest +WinHttpAPI(140Lines)2

（Update）
Congratulations! The above two files no longer cause false positives.
Defender is the same version and the files are the same.
It seems to be a problem only with my PC.
From now on, I will stay calm and observe.

test9 remains a false positive.

Date	SeleniumVBA Version	Win Defender	Virus Total Score
10/19/25	SeleniumVBA.xlsm ver.6.7 test1	No Detection 1.439.290.0	4/65
10/19/25	SeleniumVBA.xlsm ver.6.7 test1 +WinHttpRequest +WinHttpAPI(140Lines)	No Detection 1.439.290.0	4/65
10/19/25	SeleniumVBA.xlsm ver.6.7 test9	Detection 1.439.290.0	4/65

[hanamichi77777]

SeleniumBasic with WebDriver automatic update tool applied is showing false positives.
WebDriver automatic update behavior using VBA is prone to false positives.

Date	SeleniumVBA Version	Win Defender	Virus Total Score
10/20/25	SeleniumBasic.xlsm + WebDriver automatic update external tool	Detection 1.439.296.0	13/66
10/20/25	SeleniumVBA.xlsm ver.6.7 test1 +WinHttpRequest +WinHttpAPI(140Lines)	No Detection 1.439.296.0	4/65