The object has no method named '<Methodname>' that matches the specified arguments

[DanielGerlach2]

Unfortunately, I have to get back in touch with you again. 😲

When using ClearScript, I noticed that the implicit conversion of parameters does not work as expected.

I have a function with the following signature:
Public Sub Send(Key As String)

When I call this function using the scriptengine with an integer parameter, I get the following error:
The object has no method named 'Send' that matches the specified arguments.

The problem can be reproduced using the following code.

Imports Microsoft.ClearScript
Imports Microsoft.ClearScript.Windows

Module Module1

    Sub Main()

        Dim pApp As New App()

        Dim strCode As String

        strCode = "App.Send ""123"", ""Test"""
        Console.WriteLine("Code:" & Environment.NewLine & strCode)
        pApp.Execute(strCode)
        Console.WriteLine("")

        strCode = "App.Send 123"
        Console.WriteLine("Code:" & Environment.NewLine & strCode)
        pApp.Execute(strCode)
        Console.WriteLine("")

    End Sub

End Module

Public Class App

    Public Sub Send(Key As String, Optional Caption As String = "Dialogcaption")
        Console.WriteLine(Caption & ": '" & Key & "'")
    End Sub


    Public Sub Execute(Expression As String)
        Dim pFlags As WindowsScriptEngineFlags = WindowsScriptEngineFlags.MarshalDateTimeAsDate
        Dim pHIFlags As HostItemFlags

        pHIFlags += HostItemFlags.GlobalMembers

        Using engine As New VBScriptEngine(pFlags)
            engine.DisableDynamicBinding = True
            engine.AcceptEnumAsUnderlyingType = True
            engine.MarshalEnumAsUnderlyingType = True
            engine.NullImportValue = DBNull.Value

            engine.AddHostObject("App", pHIFlags, Me)

            engine.ExecuteCommand(Expression)

        End Using
    End Sub

End Class

The goal is to call the function and perform an implicit conversion from integer to string.

[ClearScriptLib]

Hi @DanielGerlach2,

.NET has no implicit integer-to-string conversion. However, you can enable the desired behavior by defining an overload:

Public Sub Send(Key As Integer, Optional Caption As String = "Dialogcaption")
    Send(CStr(Key), Caption)
End Sub

Or, you could define Key as Object in the overload to provide automatic conversion for any input type. And if you'd prefer not to pollute App with such overloads, you could instead define an extension module:

Public Module AppExtensions
    <Extension>
    Public Sub Send(pApp As App, Key As Object, Optional Caption As String = "Dialogcaption")
        pApp.Send(CStr(Key), Caption)
    End Sub
End Module

And then:

engine.AddHostType(GetType(AppExtensions))

Good luck!