Invalid conversion from type HostIndexedProperty to type Boolean

[DanielGerlach2]

Hello ClearScript Team,

The update to ClearScript 7.5.1 resolved several issues regarding its integration into our application. 👍
See here.

However, I have now discovered a new problem 😟

There are properties defined as Booleans.
e.g.
Public ReadOnly Property AdminMode() As Boolean

When evaluating them via the script engine, I receive the following error message:
ScriptEngine.Evaluate("App.AdminMode") -> Invalid conversion from type HostIndexedProperty to type Boolean

The evaluation of ScriptEngine.Evaluate("App.AdminMode = True"), however, works as expected.

Is there a switch or setting that allows me to change this behavior?
Ideally, only the return value of the property should be evaluated/returned.
Unfortunately, modifying the affected code is not possible, as this can be flexibly utilized and configured by users themselves; consequently, this approach would no longer be manageable or maintainable.

Or is the side effectreferring to related to the MarshalEnumAsUnderlyingType or AcceptEnumAsUnderlyingType attributes?

best regards
Daniel

[ClearScriptLib]

Hi @DanielGerlach2,

We've tested the following with ClearScript 7.5.0 and 7.5.1. The behavior is identical and correct, as far as we can tell:

Imports System
Imports Microsoft.ClearScript.Windows
Public Class App
    Public Sub New(adminMode As Boolean)
        Me.AdminMode = adminMode
    End Sub
    Public ReadOnly Property AdminMode() As Boolean
End Class
Module Program
    Sub Main(args As String())
        Using engine As New VBScriptEngine
            engine.DisableDynamicBinding = True
            engine.AcceptEnumAsUnderlyingType = True
            engine.MarshalEnumAsUnderlyingType = True
            engine.AddHostObject("App", new App(True))
            Console.WriteLine(engine.Evaluate("App.AdminMode"))
        End Using
    End Sub
End Module

This app prints "True" with both ClearScript versions – 7.5.0 without the enum marshaling flags, and 7.5.1 with and without them. Are you doing something differently?

Thanks!

[DanielGerlach2]

I attempted to reproduce the issue in a small test project, but so far I have not been successful. 😞

The execution flow in our application is somewhat complex; however, I will do my best to outline the scenario below and provide a simplified code example at the end. With your deeper insight into the internal processing, you may be able to identify or reproduce the behavior.

The statement to be evaluated is returned by the scriptengine using Evaluate, producing the following results:

• Evaluate("App.Session.IsAdminMember") is returned as {HostIndexedProperty:IsAdminMember}
• Evaluate("App.Session.IsAdminMember = true") is returned as True

The problem also seems to lie at the object level; Evaluating the properties of a subclass appears to be the sticking point here, as direct access to properties of the App works as expected: 😲

• Evaluate("App.AdminMode") is returned as True
• Evaluate("App.AminMode = true") is returned as True

If, however, the expression to be evaluated contains additional logic conditions, the evaluation works correctly—for example:

• Evaluate("App.Session.IsAdminMember OR 1 = 1") is returned as True

The originally reported error Invalid conversion from type HostIndexedProperty to type Boolean resulted from subsequent instructions attempting to output the returned value as a Boolean.

Imports Microsoft.ClearScript
Imports Microsoft.ClearScript.Windows

Module Module1

    Sub Main()

        Dim pApp As New App(True)

        Dim strCode As String

        strCode = "App.Session.IsAdminMember"

        Console.WriteLine(pApp.Eval(strCode))

        strCode = "App.Session.IsAdminMember = True"

        Console.WriteLine(pApp.Eval(strCode))
    End Sub

End Module

Public Class App
    Public Sub New(adminMode As Boolean)
        Me.AdminMode = adminMode
        Me.Session = New Session(adminMode)
    End Sub

    Public ReadOnly Property AdminMode() As Boolean

    Public Property Session As Session

    Public Function Eval(Expression As String) As Object
        Dim pFlags As WindowsScriptEngineFlags = WindowsScriptEngineFlags.MarshalDateTimeAsDate
        Dim pHIFlags As HostItemFlags

        pHIFlags += HostItemFlags.GlobalMembers

        Using engine As New VBScriptEngine(pFlags)
            engine.DisableDynamicBinding = True
            engine.AcceptEnumAsUnderlyingType = True
            engine.MarshalEnumAsUnderlyingType = True
            engine.NullImportValue = DBNull.Value

            engine.AddHostObject("App", pHIFlags, Me)

            Return engine.Evaluate(Expression)
        End Using

    End Function

End Class

Public Class Session

    Public Sub New(IsAdminMember As Boolean)
        Me.IsAdminMember = IsAdminMember
    End Sub

    Public ReadOnly Property IsAdminMember() As Boolean

End Class

Do you have any idea what could be causing this behavior?

I had also suspected that the problem stemmed from incorporating objects from classes within other DLLs; however, I was unable to confirm this through further evaluation of objects (all of which belonged to the main project).
For example, evaluating App.DialogObject.Dialog.Settings.IsVisible also returns HostIndexedProperty instead of the Boolean value of the property.

[DanielGerlach2]

After further testing, the issue is not due to the complexity of our code or object level, but rather to a feature of VB.NET.

In VB.NET, it is possible to define properties with parameters. see here
This corresponds more or less to indexers in C#, which explains the message "HostIndexedProperty".

The behavior can be reproduced using the following code.

Imports Microsoft.ClearScript
Imports Microsoft.ClearScript.Windows

Module Module1

    Sub Main()

        Dim pApp As New App(True)

        pApp.Session = New Session(True)

        Dim strCode As String

        strCode = "App.Session.IsAdminMember"

        Console.WriteLine("Code:" & Environment.NewLine & strCode)
        Console.WriteLine(pApp.Eval(strCode))

        strCode = "App.Session.IsAdminMember = True"
        Console.WriteLine()
        Console.WriteLine("Code:" & Environment.NewLine & strCode)
        Console.WriteLine(pApp.Eval(strCode))


        strCode = "App.Session.IsAdminMember AND 1=1"
        Console.WriteLine()
        Console.WriteLine("Code:" & Environment.NewLine & strCode)
        Console.WriteLine(pApp.Eval(strCode))
    End Sub

End Module

Public Class App
    Public Sub New(adminMode As Boolean)
        Me.AdminMode = adminMode
    End Sub
    Public ReadOnly Property AdminMode() As Boolean

    Public Property Session As Session

    Public Function Eval(Expression As String) As Object
        Dim pFlags As WindowsScriptEngineFlags = WindowsScriptEngineFlags.MarshalDateTimeAsDate
        Dim pHIFlags As HostItemFlags

        pHIFlags += HostItemFlags.GlobalMembers

        Using engine As New VBScriptEngine(pFlags)
            engine.DisableDynamicBinding = True
            engine.AcceptEnumAsUnderlyingType = True
            engine.MarshalEnumAsUnderlyingType = True
            engine.NullImportValue = DBNull.Value

            engine.AddHostObject("App", pHIFlags, Me)

            Return engine.Evaluate(Expression)
        End Using

    End Function

End Class

Public Class Session

    Dim mvarIsAdminMember As Boolean
    Dim mvarBuffered As Boolean

    Public Sub New(IsAdminMember As Boolean)
        Me.IsAdminMember = IsAdminMember
    End Sub

    Public Property IsAdminMember(Optional buffered As Boolean = False) As Boolean
        Get
            If buffered Then
                Return mvarIsAdminMember
            Else
                Return mvarIsAdminMember
            End If
        End Get
        Set(value As Boolean)
            If buffered Then
                mvarIsAdminMember = value
            Else
                mvarIsAdminMember = value
            End If
        End Set
    End Property

End Class

Can the desired behavior be achieved via a setting in the scriptengine, or is this feature potentially not yet supported in ClearScript?

[ClearScriptLib]

Hi @DanielGerlach2,

In VB.NET, it is possible to define properties with parameters

Yes, and ClearScript supports such properties. As your example demonstrates, VBScript code has full access to IsAdminMember and can use it via its native syntax. However, the specific behavior you're seeing deserves an explanation.

When script code invokes a parameterized (or indexed) property without arguments, ClearScript returns a special object – a host indexed property. It does that to accommodate languages like JavaScript that don't support indexed properties and must access them via intermediaries.

A host indexed property is designed to work naturally with VBScript by providing a default property bound to the target – IsAdminMember in this case. VBScript invokes default properties automatically to convert objects into values, but until it needs a value – that is, until the code uses the object in an arithmetic or logical expression – VBScript defers that conversion. That's what's happening in your example.

Nevertheless, you can use reflection to retrieve the property value on the .NET side:

Dim pRetVal = engine.Evaluate(Expression)
If pRetVal IsNot Nothing Then
    Dim pType = pRetVal.GetType()
    If pType.FullName = "Microsoft.ClearScript.HostIndexedProperty" Then
        Dim pNoArgs = Array.Empty(Of Object)()
        Dim pArgs As Object() = { engine, BindingFlags.GetField, pNoArgs, pNoArgs, Nothing }
        If CBool(pType.InvokeMember("TryInvoke", BindingFlags.InvokeMethod, Nothing, pRetVal, pArgs)) Then
            pRetVal = pArgs(4)
        End If
    End If
End If

Good luck!

[DanielGerlach2]

Thank you very much for the explanation and the example code.
It now works exactly as desired. 👍