✨ Support for Tweening Multiple Animations at Once

[XanBelOr]

🛑 Before you Start

• I have searched existing feature requests for my feature.
• I have read the documentation, and I am sure this feature is not already implemented.
• I am using the latest version of Animated Java.
• I will only request a single feature in this request. If I have multiple feature requests, I will create a separate request for each one.

📝 Description

Tweening animations currently is only supported for one at a time, tween functions currently pause all animations and start a new one. Tweening also uses one scoreboard objective for every animation (not a bug, just current behavior which works as intended).

💡 Describe the solution you'd like

The option to support multiple animations being tweened at once (not necessarily replacing current functionality). This function would:

• not pause every animation
• only modify the interpolation of the enabled bones for that animation
• use a unique scoreboard objective for that specific animation instead of using the same aj.tween_duration objective.

🧪 Describe alternatives you've considered

Currently, I have separate functions in my project that adds this functionality for specific custom entities, but I have to use return run <my modified function> in the on_tick functions for the animations I need to be tweened at the same time, but the obvious issue is having to add that in after every export.

[SnaveSutit]

If you could show me the modifications you've made to your exported Data Pack that would be very helpful

[XanBelOr]

If you could show me the modifications you've made to your exported Data Pack that would be very helpful

Here is an example function of a modified tween function:

tag @s add aj.nullifier.animation.throw_lightnings_melee.playing
$scoreboard players set @s wla.boss.nullifier.throw_lightnings_melee_tween $(duration)
$scoreboard players set @s aj.throw_lightnings_melee.frame $(to_frame)
scoreboard players operation #this aj.i = @s wla.boss.nullifier.throw_lightnings_melee_tween
tag @s add aj.transforms_only
execute at @s run function animated_java:nullifier/animations/throw_lightnings_melee/zzz/apply_frame {frame: 0}
$execute at @s run function animated_java:nullifier/animations/throw_lightnings_melee/zzz/apply_frame {frame: $(to_frame)}
tag @s remove aj.transforms_only
#execute on passengers store result entity @s interpolation_duration int 1 run scoreboard players get #this aj.i
execute on passengers if entity @s[tag=aj.global.data] run function namespace/affect_certain_bones_only with entity @s data.uuids_by_name

It does not call the pause_all function, uses a unique score to track its duration, and replaces the command that sets all of the bone's interpolation with a command that only affects the enabled bones of that animation. See below.

Example of affect_certain_bones_only:

$execute store result entity $(bone_rightlowerarm) interpolation_duration int 1 run scoreboard players get #this aj.i 
$execute store result entity $(bone_rightupperarm) interpolation_duration int 1 run scoreboard players get #this aj.i 
$execute store result entity $(bone_leftlowerarm) interpolation_duration int 1 run scoreboard players get #this aj.i 
$execute store result entity $(bone_leftupperarm) interpolation_duration int 1 run scoreboard players get #this aj.i 
$execute store result entity $(bone_head) interpolation_duration int 1 run scoreboard players get #this aj.i 
$execute store result entity $(bone_cape) interpolation_duration int 1 run scoreboard players get #this aj.i 
$execute store result entity $(bone_body) interpolation_duration int 1 run scoreboard players get #this aj.i 

And finally, I use a slightly modified version of the animations on_tick function to use the unique tween score instead of the global one:

# This file was generated by Animated Java via MC-Build. It is not recommended to edit this file directly.
scoreboard players remove @s wla.boss.nullifier.throw_lightnings_melee_tween 1
execute if score @s wla.boss.nullifier.throw_lightnings_melee_tween matches 1.. run return 1
execute if score @s wla.boss.nullifier.throw_lightnings_melee_tween matches 0 on passengers run data modify entity @s interpolation_duration set value 1
data remove storage animated_java:temp args
execute store result storage animated_java:temp args.frame int 1 run scoreboard players get @s aj.throw_lightnings_melee.frame
function animated_java:nullifier/animations/throw_lightnings_melee/zzz/apply_frame with storage animated_java:temp args
execute if score @s aj.throw_lightnings_melee.frame matches 62.. run return run function animated_java:nullifier/animations/throw_lightnings_melee/pause
scoreboard players add @s aj.throw_lightnings_melee.frame 1

It's still very similar to the existing tween logic, but allows for tweening multiple animations at once.